File Coverage

blib/lib/Map/Metro/Emitter.pm

Criterion	Covered	Total	%
statement	58	80	72.5
branch	8	30	26.6
condition			n/a
subroutine	17	22	77.2
pod	0	1	0.0
total	83	133	62.4

use Map::Metro::Standard;
use strict;
use warnings;

our $VERSION = '0.2300'; # VERSION
# ABSTRACT: Event emitter for hooks

package Map::Metro::Emitter {

    use Moose;
    use Kavorka;
    use List::Util 1.33 'none';
    use Types::Standard -types;
    use Map::Metro::Hook;

    use Module::Pluggable search_path => ['Map::Metro::Plugin::Hook'], require => 1, sub_name => 'found_plugins';

    has wanted_hook_plugins => (
        is => 'ro',
        isa => ArrayRef[ Str ],
        traits => ['Array'],
        handles => {
            all_wanted_hook_plugins => 'elements',
        },
    );
    has registered_hooks => (
        is => 'rw',
        isa => ArrayRef,
        traits => ['Array'],
        handles => {
            add_registered_hook => 'push',
            all_registered_hooks => 'elements',
            filter_registered_hooks => 'grep',
        },
    );
    has plugins => (
        is => 'rw',
        isa => HashRef,
        traits => ['Hash'],
        handles => {
            add_plugin => 'set',
            get_plugin => 'get',
            plugin_names => 'keys',
        },
    );

    sub BUILD {
        my $self = shift;

        PLUGIN:
        foreach my $pluginname ($self->found_plugins) {
            my $actual = $pluginname =~ s{^Map::Metro::Plugin::Hook::}{}r;
            next PLUGIN if none { $_ eq $actual } $self->all_wanted_hook_plugins;

            my $plugin = $pluginname->new;
            $self->register($plugin);
            $self->add_plugin($actual => $plugin);
        }
    }
    method register($plugin) {
        my %hooks_list = $plugin->register;

        foreach my $event (keys %hooks_list) {
            my $hook = Map::Metro::Hook->new(event => $event, action => $hooks_list{ $event }, plugin => $plugin);
            $self->add_registered_hook($hook);
        }
    }

    method before_add_station($station) {
        $self->emit('before_add_station', $station);
    }
    method before_add_routing($routing) {
        $self->emit('before_add_routing', $routing);
    }
    method before_start_routing {
        $self->emit('before_start_routing');
    }

    method emit($event, @args) {
        my @hooks = $self->filter_registered_hooks(sub { $_->event eq $event });

        foreach my $hook (@hooks) {
            $hook->action->($hook->plugin, @args);
        }
    }
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Map::Metro::Emitter - Event emitter for hooks

=head1 VERSION

Version 0.2300, released 2016-01-14.

=head1 SOURCE

L<https://github.com/Csson/p5-Map-Metro>

=head1 HOMEPAGE

L<https://metacpan.org/release/Map-Metro>

=head1 AUTHOR

Erik Carlsson <[e-mail]>

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2016 by Erik Carlsson.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut