File Coverage

blib/lib/Mail/LMLM.pm

Criterion	Covered	Total	%
statement	46	96	47.9
branch	0	18	0.0
condition	0	2	0.0
subroutine	16	19	84.2
pod	2	2	100.0
total	64	137	46.7

package Mail::LMLM;
$Mail::LMLM::VERSION = '0.6807';
use strict;
use warnings;
use autodie;

use 5.008;

use parent 'Mail::LMLM::Object';

use Mail::LMLM::Render::HTML        ();
use Mail::LMLM::Types::Ezmlm        ();
use Mail::LMLM::Types::Egroups      ();
use Mail::LMLM::Types::Listar       ();
use Mail::LMLM::Types::Majordomo    ();
use Mail::LMLM::Types::Listserv     ();
use Mail::LMLM::Types::Mailman      ();
use Mail::LMLM::Types::GoogleGroups ();

use vars qw(%mailing_list_classes);

my $prefix = "Mail::LMLM::Types::";

sub _pref
{
    my $name = shift;

    return $prefix . $name;
}

%mailing_list_classes = (
    (
        map { $_ => _pref( ucfirst($_) ) } (
            'egroups', 'ezmlm', 'listar', 'majordomo', 'listserv', 'mailman'
        )
    ),
    "google" => _pref("GoogleGroups"),
);

use vars qw(@render_what);

@render_what = (
    {
        'title' => "Description",
        'func'  => "render_description",
        'id'    => "desc",
    },
    {
        'title' => "Posting Guidelines",
        'func'  => "render_guidelines",
        'id'    => "post_guidelines",
    },
    {
        'title' => "Subscribing to the Mailing-List",
        'func'  => "render_subscribe",
        'id'    => "subscribe",
    },
    {
        'title' => "Unsubscribing from the Mailing-List",
        'func'  => "render_unsubscribe",
        'id'    => "unsubscribe",
    },
    {
        'title' => "Posting Messages to the Mailing-List",
        'func'  => "render_post",
        'id'    => "posting",
    },
    {
        'title' => "Contacting the Mailing-List's Owner",
        'func'  => "render_owner",
        'id'    => "owner",
    },
    {
        'title' => "The Mailing-List's Homepage",
        'func'  => "render_homepage",
        'id'    => "homepage",
    },
    {
        'title' => "Online Messages Archive",
        'func'  => "render_online_archive",
        'id'    => "archive",
    },
);

sub _do_nothing
{
}

sub initialize
{
    my $self = shift;

    $self->{'title'}         = "List of Mailing Lists";
    $self->{'headline'}      = "List of Mailing Lists";
    $self->{'prolog'}        = $self->{'epilog'} = \&_do_nothing;
    $self->{'extra_classes'} = {};
    while ( scalar(@_) )
    {
        my $key   = shift;
        my $value = shift;
        if ( $key =~ /^-?lists$/ )
        {
            $self->{'lists'} = $value;
        }
        elsif ( $key =~ /^-?title$/ )
        {
            $self->{'title'} = $value;
        }
        elsif ( $key =~ /^-?headline$/ )
        {
            $self->{'headline'} = $value;
        }
        elsif ( $key =~ /^-?extra-classes$/ )
        {
            $self->{'extra_classes'} = $value;
        }
        elsif ( $key =~ /^-?prolog$/ )
        {
            $self->{'prolog'} = $value;
        }
        elsif ( $key =~ /^-?epilog$/ )
        {
            $self->{'epilog'} = $value;
        }
    }

    if ( !exists( $self->{'lists'} ) )
    {
        die "The lists were not defined for Mail::LMLM!";
    }
    return 0;
}

sub render
{
    my $self = shift;

    open my $index_fh, ">", "index.html";
    my $main_r = Mail::LMLM::Render::HTML->new( \$index_fh );

    $main_r->start_document( $self->{'title'}, $self->{'headline'}, );

    $self->{'prolog'}->( $self, $main_r );

    foreach my $mailing_list ( @{ $self->{'lists'} } )
    {
        my $filename = $mailing_list->{'id'} . ".html";
        open my $o_fh, ">", $filename;
        my $r = Mail::LMLM::Render::HTML->new( \$o_fh );

        my $class_name = $mailing_list->{'class'};
        my $class =
               $mailing_list_classes{$class_name}
            || $self->{'extra_classes'}->{$class_name}
            || die "Mail::LMLM: Unknown Class \"$class_name\"";
        my $mail_lister = (
            ( ref($class) eq "CODE" )
            ? $class->(%$mailing_list)
            : $class->new(%$mailing_list)
        );

        my $title =
            exists( $mailing_list->{'title'} )
            ? $mailing_list->{'title'}
            : $mailing_list->{'id'};

        $r->start_document( $title, $title );

        foreach my $what (@render_what)
        {
            my $func = $what->{'func'};
            $r->start_section( $what->{'title'}, +{ 'id' => $what->{'id'} } );
            $mail_lister->$func($r);
            $r->end_section();
        }

        $main_r->start_section( $title, { 'title_url' => $filename } );
        $mail_lister->render_description($main_r);
        $main_r->end_section();

        $r->end_document();

        close($o_fh);
    }

    $self->{'epilog'}->( $self, $main_r );

    $main_r->end_document();
    close($index_fh);

    open my $STYLE, ">", "style.css";
    print {$STYLE} <<"EOF";
a:hover { background-color : LightGreen }
div.indent { margin-left : 3em }
EOF

    close($STYLE);
}

#### Documentation

__END__