File Coverage

blib/lib/Mackerel/Webhook/Receiver.pm

Criterion	Covered	Total	%
statement	41	52	78.8
branch	8	14	57.1
condition	2	2	100.0
subroutine	11	12	91.6
pod	0	4	0.0
total	62	84	73.8

package Mackerel::Webhook::Receiver;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.01";

use JSON;
use Plack::Request;

use Mackerel::Webhook::Receiver::Event;

use Class::Accessor::Lite (
    new => 1,
);
sub events { shift->{events} ||= {} }

sub to_app {
    my $self = shift;
    sub {
        my $env = shift;
        my $req = Plack::Request->new($env);
        if ($req->method ne 'POST') {
            return [400, [], ['BAD REQUEST']];
        }

        my $payload = eval { decode_json $req->content }
            or return [400, [], ['BAD REQUEST']];

        my $event_name = $payload->{event};
        my $event = Mackerel::Webhook::Receiver::Event->new(
            payload => $payload,
            event   => $event_name,
        );

        if (my $code = $self->events->{''}) {
            $code->($event, $req);
        }
        if (my $code = $self->events->{$event_name}) {
            $code->($event, $req);
        }

        [200, [], ['OK']];
    };
}

sub on {
    my $self = shift;
    my ($event, $code) = @_;
    if (ref $event eq 'CODE') {
        $code  = $event;
        $event = '';
    }
    $self->events->{$event} = $code;
}

sub run {
    my $self = shift;
    my %opts = @_ == 1 ? %{$_[0]} : @_;

    my %server;
    my $server = delete $opts{server};
    $server{server} = $server if $server;

    my @options = %opts;
    require Plack::Runner;

    my $runner = Plack::Runner->new(
        %server,
        options => \@options,
    );
    $runner->run($self->to_app);
}

1;
__END__