File Coverage

blib/lib/Log/ger/Plugin/WithDie.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	6	8	75.0
condition	6	6	100.0
subroutine	13	13	100.0
pod	0	2	0.0
total	56	60	93.3

package Log::ger::Plugin::WithDie;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-03-11'; # DATE
our $DIST = 'Log-ger-Plugin-WithWarn'; # DIST
our $VERSION = '0.004'; # VERSION

use strict;
use warnings;

use Log::ger ();

sub meta { +{
    v => 2,
} }

sub get_hooks {
    my %plugin_conf = @_;

    return {
        create_routine_names => [
            __PACKAGE__, 50,
            sub {
                my %args = @_;

                my $levels = \%Log::ger::Levels;

                return [{
                    logger_subs => [
                        (map { ["log_${_}_die", $_, "default"] }
                             grep {$levels->{$_} > 0 && $levels->{$_} <= 20} keys %$levels),
                    ],
                    level_checker_subs => [],
                    logger_methods => [
                        (map { ["${_}_die", $_, "default"] }
                             grep {$levels->{$_} > 0 && $levels->{$_} <= 20} keys %$levels),
                    ],
                    level_checker_methods  => [
                    ],
                }, 0];
            }],
        before_install_routines => [
            __PACKAGE__, 50,
            sub {
                my %args = @_;

                # wrap the logger
                for my $r (@{ $args{routines} }) {
                    my ($code, $name, $numlevel, $type) = @$r;
                    if ($type =~ /^log(ger)?_sub/ && $name =~ /\Alog_\w+_die\z/) {
                        $r->[0] = sub {
                            $code->(@_);
                            die $args{formatters}{default}(@_)."\n";
                        };
                    } elsif ($type =~ /^log(ger)?_method/ && $name =~ /\A\w+_die\z/) {
                        $r->[0] = sub {
                            $code->(@_);
                            shift;
                            die $args{formatters}{default}(@_)."\n";
                        };
                    }
                }
            },
        ],
    };
}

1;
# ABSTRACT: Add *_die logging routines

__END__