File Coverage

blib/lib/Log/ger/Output/Perl.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	13	16	81.2
condition	2	5	40.0
subroutine	6	6	100.0
pod	0	1	0.0
total	54	61	88.5

package Log::ger::Output::Perl;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-03-07'; # DATE
our $DIST = 'Log-ger-Output-Perl'; # DIST
our $VERSION = '0.002'; # VERSION

use 5.010001;
use strict;
use warnings;
use Log::ger::Util ();

sub get_hooks {
    my %plugin_conf = @_;

    my $action = delete($plugin_conf{action}) || {
        warn  => 'warn',
        error => 'warn',
        fatal => 'die',
    };
    keys %plugin_conf and die "Unknown configuration: ".
        join(", ", sort keys %plugin_conf);

    return {
        create_outputter => [
            __PACKAGE__, # key
            # we want to handle all levels, thus we need to be higher priority
            # than default Log::ger hooks (10) which will install null loggers
            # for less severe levels.
            9,           # priority
            sub {        # hook
                my %hook_args = @_;

                my $outputter = sub {
                    my ($per_target_conf, $msg, $per_msg_conf) = @_;
                    my $lvl = $per_msg_conf->{level} // $hook_args{level};
                    if (my $act =
                            $action->{Log::ger::Util::string_level($lvl)}) {
                        @_ = ref $msg eq 'ARRAY' ? @$msg : ($msg);
                        if ($act eq 'warn') {
                            warn @_;
                        } elsif ($act eq 'carp') {
                            require Carp;
                            goto &Carp::carp;
                        } elsif ($act eq 'cluck') {
                            require Carp;
                            goto &Carp::cluck;
                        } elsif ($act eq 'croak') {
                            require Carp;
                            goto &Carp::croak;
                        } elsif ($act eq 'confess') {
                            require Carp;
                            goto &Carp::confess;
                        } else {
                            # die is the default action if unknown
                            die @_;
                        }
                    }
                };
                [$outputter];
            }],
    };
}

1;
# ABSTRACT: Log to Perl's standard facility (warn, die, etc)

__END__