File Coverage

blib/lib/Log/Syslog/Fast/Simple.pm

Criterion	Covered	Total	%
statement	70	70	100.0
branch	2	4	50.0
condition	21	35	60.0
subroutine	16	16	100.0
pod	2	2	100.0
total	111	127	87.4

package Log::Syslog::Fast::Simple;

use strict;
use warnings;

use Log::Syslog::Fast ':all';
use Sys::Hostname;

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT      = qw();
our %EXPORT_TAGS = %Log::Syslog::Fast::Constants::EXPORT_TAGS;
our @EXPORT_OK   = @Log::Syslog::Fast::Constants::EXPORT_OK;

use constant _LOGGERS   => 0;
use constant _ARGS      => 1;

use constant _PROTO     => 0;
use constant _HOSTNAME  => 1;
use constant _PORT      => 2;
use constant _FACILITY  => 3;
use constant _SEVERITY  => 4;
use constant _SENDER    => 5;
use constant _NAME      => 6;
use constant _FORMAT    => 7;

sub new {
    my $what = shift;
    my $class = ref $what || $what;

    my $default_name = $0;
    $default_name =~ s,.*/,,;
    $default_name =~ s/[^\w.-_]//g;

    my $args = (@_ == 1 && ref $_[0] eq 'HASH') ? $_[0] : {@_};

    $args->{proto}      ||= LOG_UDP;
    $args->{hostname}   ||= '127.0.0.1';
    $args->{port}       ||= 514;
    $args->{facility}   ||= LOG_LOCAL0;
    $args->{severity}   ||= LOG_INFO;
    $args->{sender}     ||= Sys::Hostname::hostname;
    $args->{name}       ||= $default_name;
    $args->{format}     ||= LOG_RFC3164;

    return bless [
        [],    # loggers
        [@{ $args }{qw/
            proto hostname port facility severity sender name format
        /}],
    ], $class;
}

sub send {
    my $severity = $_[3] || $_[0][_ARGS][_SEVERITY];
    my $facility = $_[4] || $_[0][_ARGS][_FACILITY];

    my $logger = $_[0][_LOGGERS][$facility][$severity];
    if (!$logger) {
        my @args = @{ $_[0][_ARGS] };
        $args[_FACILITY] = $facility;
        $args[_SEVERITY] = $severity;

        my $format = pop(@args);
        $logger = $_[0][_LOGGERS][$facility][$severity] = Log::Syslog::Fast->new(@args);
        $logger->set_format($format);
    }

    return $logger->send($_[1], $_[2] || time);
}

1;
__END__