File Coverage

blib/lib/Log/StringFormatter.pm

Criterion	Covered	Total	%
statement	54	55	98.1
branch	9	10	90.0
condition	8	18	44.4
subroutine	15	15	100.0
pod	1	1	100.0
total	87	99	87.8

package Log::StringFormatter;

use 5.008005;
use strict;
use warnings;
use base qw/Exporter/;

our $VERSION = "0.02";
our @EXPORT = qw/stringf/;

sub stringf {
    my $message = '';
    if ( @_ == 1 && defined $_[0]) {
        $message = '' . Log::StringFormatter::Dumper->new($_[0]);
    }
    elsif ( @_ >= 2 )  {
        $message = sprintf(shift, map { Log::StringFormatter::Dumper->new($_) } @_);
    }
    return $message;
}

1;

package
    Log::StringFormatter::Dumper;

use strict;
use warnings;
use base qw/Exporter/;
use Data::Dumper;
use Scalar::Util qw/blessed/;

use overload
    '""' => \&stringfy,
    '0+' => \&numeric,
    fallback => 1;

sub new {
    my ($class, $value) = @_;
    bless \$value, $class;
}

sub stringfy {
    my $self = shift;
    my $value = $$self;
    if ( blessed($value) && (my $stringify = overload::Method( $value, '""' ) || overload::Method( $value, '0+' )) ) {
        $value = $stringify->($value);
    }
    dumper($value);
}

sub numeric {
    my $self = shift;
    my $value = $$self;
    if ( blessed($value) && (my $numeric = overload::Method( $value, '0+' ) || overload::Method( $value, '""' )) ) {
        $value = $numeric->($value);
    }
    $value;
}

sub dumper {
    my $value = shift;
    if ( defined $value && ref($value) ) {
        local $Data::Dumper::Terse = 1;
        local $Data::Dumper::Indent = 0;
        local $Data::Dumper::Sortkeys = 1;
        $value = Data::Dumper::Dumper($value);
    }
    $value;
}


1;


1;
__END__