File Coverage

blib/lib/Log/Any/Plugin/ContextStack.pm

Criterion	Covered	Total	%
statement	48	51	94.1
branch	6	10	60.0
condition			n/a
subroutine	14	14	100.0
pod	1	1	100.0
total	69	76	90.7

package Log::Any::Plugin::ContextStack;
# ABSTRACT: Stack of context items that get prepended to each log message
$Log::Any::Plugin::ContextStack::VERSION = '0.012';
use strict;
use warnings;
use Carp qw( confess );
use Log::Any;
use Scope::Guard qw( guard );

use Log::Any::Plugin::Util qw( get_old_method set_new_method );
use Log::Any::Adapter::Util qw( logging_methods );

my @context_stack;
my $stringify_context = \&_default_stringify_context;

sub install {
    my ($class, $adapter_class, %args) = @_;

    if ($args{stringify}) {
        $stringify_context = delete $args{stringify};
    }

    if (%args) {
        my $keys = join(', ', sort keys %args);
        confess("Unexpected arguments $keys");
    }

    # Create the $log->push method
    set_new_method($adapter_class, push_context => sub {
        my $self = shift;
        push(@context_stack, @_);
        return $self;
    });

    # Create the $log->pop method
    set_new_method($adapter_class, pop_context => sub {
        my $self = shift;
        return pop(@context_stack);
    });

    # Create the $log->context method
    set_new_method($adapter_class, push_scoped_context => sub {
        my $self = shift;
        return unless @_;
        my $count = scalar @_;
        push(@context_stack, @_);
        return guard { splice(@context_stack, -$count) };
    });

    # Augment the main $log->debug methods (not the aliases)
    for my $method_name ( logging_methods() ) {
        my $old_method = get_old_method($adapter_class, $method_name);
        set_new_method($adapter_class, $method_name, sub {
            my $self = shift;
            if (@context_stack) {
                unshift(@_, $stringify_context->(\@context_stack));
            }
            $old_method->($self, @_);
        });
    }
}

sub _default_stringify_context {
    my ($context) = @_;
    return '' unless @$context;
    return '[' . join(':', @$context) . ']';
}

1;

__END__