File Coverage

blib/lib/Log/Any/Plugin/Stringify.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch	2	2	100.0
condition	2	2	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	40	40	100.0

package Log::Any::Plugin::Stringify;
# ABSTRACT: Custom argument stringification plugin for log adapters
$Log::Any::Plugin::Stringify::VERSION = '0.007';
use strict;
use warnings;

use Log::Any::Plugin::Util qw(
    all_logging_methods get_old_method set_new_method
);

use Data::Dumper;

sub install {
    my ($class, $adapter_class, %args) = @_;

    my $stringifier = $args{stringifier} || \&default_stringifier;

    # Inject the stringifier into the existing logging methods
    #
    for my $method_name ( all_logging_methods() ) {
        my $old_method = get_old_method($adapter_class, $method_name);
        set_new_method($adapter_class, $method_name, sub {
            my $self = shift;
            $self->$old_method($stringifier->(@_));
        });
    }
}

sub default_stringifier {
    my (@args) = @_;

    local $Data::Dumper::Indent    = 0;
    local $Data::Dumper::Pair      = '=';
    local $Data::Dumper::Quotekeys = 0;
    local $Data::Dumper::Sortkeys  = 1;
    local $Data::Dumper::Terse     = 1;

    return join('', map { ref $_ ? Dumper($_) : $_ } @args);
}

1;

__END__