File Coverage

lib/Log/Any/Adapter/Mojo.pm

Criterion	Covered	Total	%
statement	27	35	77.1
branch			n/a
condition	1	3	33.3
subroutine	9	11	81.8
pod	0	1	0.0
total	37	50	74.0

package Log::Any::Adapter::Mojo;

BEGIN {
    $Log::Any::Adapter::Mojo::VERSION = '0.06';
}

use strict;
use warnings;
use Log::Any::Adapter::Util qw(make_method);
use base qw(Log::Any::Adapter::Base);

use Mojo::Log;

sub init {
    my ($self) = @_;
    $self->{logger} ||= Mojo::Log->new;
}

# Create logging methods
#
foreach my $method ( Log::Any->logging_methods ) {
    my $mojo_method = $method;

    # Map log levels down to Mojo::Log levels where necessary
    #
    for ($mojo_method) {
        s/trace/debug/;
        s/notice/info/;
        s/warning/warn/;
        s/critical|alert|emergency/fatal/;
    }

    make_method(
        $method,
        sub {
            my $self = shift;
            my ( $pkg, $line ) = ( caller() )[ 0, 2 ];

            # Quick and dirty hack to get correct package and line number
            # into log line.
            no warnings;

            my $old_syswrite = *{*IO::Handle::syswrite}{CODE};
            local *IO::Handle::syswrite = sub {
                my $self = shift;
                my $l    = shift;

                $l =~ s/Log::Any::Adapter::Mojo:\d+/\Q$pkg\E:\Q$line\E/;
                $l =~ s/Mojo::EventEmitter:\d+/\Q$pkg\E:\Q$line\E/;
                $l =~ s/Mojo::Log:\d+/\Q$pkg\E:\Q$line\E/;

                return $self->$old_syswrite( $l, @_ );
            };

            return $self->{logger}->$mojo_method(@_);
        }
    );
}

# Create detection methods: is_debug, is_info, etc.
#
foreach my $method ( Log::Any->detection_methods ) {
    my $mojo_method = $method;

    # Map log levels down to Mojo::Log levels where necessary
    #
    for ($mojo_method) {
        s/trace/debug/;
        s/notice/info/;
        s/warning/warn/;
        s/critical|alert|emergency/fatal/;
    }

    make_method(
        $method,
        sub {
            my $self = shift;
            return $self->{logger}->$mojo_method(@_);
        }
    );
}

1;

__END__