File Coverage

blib/lib/Locale/TextDomain/OO/Extract/Role/File.pm

Criterion	Covered	Total	%
statement	34	43	79.0
branch	3	4	75.0
condition	3	5	60.0
subroutine	8	9	88.8
pod	2	2	100.0
total	50	63	79.3

package Locale::TextDomain::OO::Extract::Role::File; ## no critic (TidyCode)

use strict;
use warnings;
use Locale::TextDomain::OO::Util::JoinSplitLexiconKeys;
use Locale::Utils::PlaceholderMaketext;
use Moo::Role;
use MooX::Types::MooseLike::Base qw(ArrayRef Bool HashRef Str);
use namespace::autoclean;

our $VERSION = '2.007';

has category => (
    is      => 'rw',
    isa     => Str,
    default => q{},
);

has domain => (
    is      => 'rw',
    isa     => Str,
    default => q{},
);

has project => (
    is  => 'rw',
    isa => sub {
        my $value = shift;
        defined $value
            or return;
        Str->($value);
        return;
    },
);

has category_stack => (
    is      => 'rw',
    isa     => ArrayRef,
    default => sub { [] },
);

has domain_stack => (
    is      => 'rw',
    isa     => ArrayRef,
    default => sub { [] },
);

has filename => (
    is       => 'rw',
    isa      => Str,
    lazy     => 1,
    default  => 'unknown',
    clearer  => '_clear_filename',
);

has lexicon_ref => (
    is      => 'rw',
    isa     => HashRef,
    lazy    => 1,
    default => sub { {} },
);

has is_maketext_format_gettext => (
    is  => 'ro',
    isa => Bool,
);

sub clear {
    my $self = shift;

    $self->category( q{} );
    $self->domain( q{} );
    $self->project(undef);
    $self->category_stack([]);
    $self->domain_stack([]);
    $self->_clear_filename;

    return;
}

my $list_if_length = sub {
    my ($item, @list) = @_;

    defined $item or return;
    length $item or return;

    return @list;
};

sub add_message {
    my ($self, $msg_ref) = @_;

    my $key_util = Locale::TextDomain::OO::Util::JoinSplitLexiconKeys->instance;
    my $format_util
        = $self->is_maketext_format_gettext
        && Locale::Utils::PlaceholderMaketext->new;

    # build the lexicon part
    my $lexicon_key = $key_util->join_lexicon_key({(
        map {
            $_ => $msg_ref->{$_};
        } qw( category domain project )
    )});
    my $lexicon
        = $self->lexicon_ref->{$lexicon_key}
        ||= {
            q{} => {
                msgstr => {
                    nplurals => 2,
                    plural   => 'n != 1',
                }
            },
        };

    # build the message part
    my $msg_key = $key_util->join_message_key({
        $format_util
        ? (
            msgid => $format_util->maketext_to_gettext( $msg_ref->{msgid} ),
            (
                map {
                    $_ => $msg_ref->{$_};
                } qw( msgctxt msgid_plural )
            ),
        )
        : (
            map {
                $_ => $msg_ref->{$_};
            } qw( msgctxt msgid msgid_plural )
        )
    });
    if ( exists $lexicon->{$msg_key} ) {
        $lexicon->{$msg_key}->{reference}->{ $msg_ref->{reference} } = undef;
        return;
    }
    $lexicon->{$msg_key} = {
        $list_if_length->( $msg_ref->{automatic}, automatic => $msg_ref->{automatic} ),
        reference => { $msg_ref->{reference} => undef },
    };

    return;
}

1;

__END__