File Coverage

blib/lib/Locale/TextDomain/OO/Lexicon/Role/File.pm

Criterion	Covered	Total	%
statement	128	131	97.7
branch	34	40	85.0
condition			n/a
subroutine	17	17	100.0
pod	1	1	100.0
total	180	189	95.2

package Locale::TextDomain::OO::Lexicon::Role::File; ## no critic (TidyCode)

use strict;
use warnings;
use Carp qw(confess);
use Encode qw(decode FB_CROAK);
use English qw(-no_match_vars $OS_ERROR);
use Locale::TextDomain::OO::Singleton::Lexicon;
use Locale::TextDomain::OO::Util::ExtractHeader;
use Locale::TextDomain::OO::Util::JoinSplitLexiconKeys;
use Moo::Role;
use MooX::Types::MooseLike::Base qw(CodeRef);
use Path::Tiny qw(path);
use namespace::autoclean;

our $VERSION = '1.034';

with qw(
    Locale::TextDomain::OO::Lexicon::Role::GettextToMaketext
    Locale::TextDomain::OO::Role::Logger
);

requires qw(
    read_messages
);

has decode_code => (
    is      => 'ro',
    isa     => CodeRef,
    lazy    => 1,
    default => sub {
        sub {
            my ($charset, $text) = @_;
            defined $text
                or return $text;

            return decode( $charset, $text, FB_CROAK );
        };
    },
);

sub _decode_messages {
    my ($self, $messages_ref) = @_;

    my $charset = lc $messages_ref->[0]->{charset};
    for my $value ( @{$messages_ref} ) {
        for my $key ( qw( msgid msgid_plural msgstr ) ) {
            if ( exists $value->{$key} ) {
                for my $text ( $value->{$key} ) {
                    $text = $self->decode_code->($charset, $text);
                }
            }
        }
        if ( exists $value->{msgstr_plural} ) {
            my $got      = @{ $value->{msgstr_plural} };
            my $expected = $messages_ref->[0]->{nplurals};
            $got <= $expected or confess sprintf
                'Count of msgstr_plural=%s but nplurals=%s for msgid="%s" msgid_plural="%s"',
                $got,
                $expected,
                ( exists $value->{msgid}        ? $value->{msgid}        : q{} ),
                ( exists $value->{msgid_plural} ? $value->{msgid_plural} : q{} );
            for my $text ( @{ $value->{msgstr_plural} } ) {
                $text = $self->decode_code->($charset, $text);
            }
        }
    }

    return;
}

sub _my_glob {
    my ($self, $file) = @_;

    my $dirname  = $file->parent;
    my $filename = $file->basename;

    # only one * allowed at all
    my $dir_star_count  = () = $dirname  =~ m{ [*] }xmsg;
    my $file_star_count = () = $filename =~ m{ [*] }xmsg;
    my $count = $dir_star_count + $file_star_count;
    $count
        or return $file;
    $count > 1
        and confess 'Only one * in dirname/filename is allowd to reference the language';

    # one * in filename
    if ( $file_star_count ) {
        ( my $file_regex = quotemeta $filename ) =~ s{\\[*]}{.*?}xms;
        return +(
            sort $dirname->children( qr{\A $file_regex \z}xms )
        );
    }

    # one * in dir
    # split that dir into left, inner with * and right
    my ( $left_dir, $inner_dir, $right_dir )
        = split qr{( [^/*]* [*] [^/]* )}xms, $dirname;
    ( my $inner_dir_regex = quotemeta $inner_dir ) =~ s{\\[*]}{.*?}xms;
    my @left_and_inner_dirs
        = path($left_dir)->children( qr{$inner_dir_regex}xms );

    return +(
        sort
        grep {
            $_->is_file;
        }
        map {
            path("$_$right_dir")->child($filename);
        }
        @left_and_inner_dirs
    );
}

sub _run_extra_commands {
    my ($self, $identifier, $instance, $next_data_code) = @_;

    if ( $identifier eq 'merge_lexicon' ) {
        my ( $from1, $from2, $to ) = (
            $next_data_code->(),
            $next_data_code->(),
            $next_data_code->(),
        );
        $instance->merge_lexicon( $from1, $from2, $to );
        return 1;
    }
    if ( $identifier eq 'copy_lexicon' ) {
        my ( $from, $to ) = ( $next_data_code->(), $next_data_code->() );
        $instance->copy_lexicon( $from, $to );
        return 1;
    }
    if ( $identifier eq 'move_lexicon' ) {
        my ( $from, $to ) = ( $next_data_code->(), $next_data_code->() );
        $instance->move_lexicon( $from, $to );
        return 1;
    }
    if ( $identifier eq 'delete_lexicon' ) {
        my $name = $next_data_code->();
        $instance->delete_lexicon($name);
        return 1;
    }

    return;
}

sub lexicon_ref {
    my ($self, $file_lexicon_ref) = @_;

    my $instance = Locale::TextDomain::OO::Singleton::Lexicon->instance;
    $self->logger and $instance->logger( $self->logger );
    my $search_dirs = $file_lexicon_ref->{search_dirs}
        or confess 'Hash key "search_dirs" expected';
    my $header_util = Locale::TextDomain::OO::Util::ExtractHeader->instance;
    my $key_util    = Locale::TextDomain::OO::Util::JoinSplitLexiconKeys->instance;
    my $data = $file_lexicon_ref->{data};
    my $index = 0;
    DATA:
    while ( $index < @{ $file_lexicon_ref->{data} } ) {
        my $identifier = $data->[ $index++ ];
        $self->_run_extra_commands(
            $identifier,
            $instance,
            sub { return $data->[ $index++ ] },
        ) and next DATA;
        my ( $lexicon_key, $lexicon_value )
            = ( $identifier, $data->[ $index++ ] );
        for my $dir ( @{ $search_dirs } ) {
            my $file = path( $dir, $lexicon_value );
            my @files = $self->_my_glob($file);
            for ( @files ) {
                my $filename = $_->canonpath;
                my $lexicon_language_key = $lexicon_key;
                my $language = $filename;
                my @parts = split m{[*]}xms, $file;
                if ( @parts == 2 ) {
                    substr $language, 0, length $parts[0], q{};
                    substr $language, - length $parts[1], length $parts[1], q{};
                    $lexicon_language_key =~ s{[*]}{$language}xms;
                }
                my $messages_ref = $self->read_messages($filename);
                my $header_msgstr = $messages_ref->[0]->{msgstr}
                    or confess 'msgstr of header not found';
                my $header_ref = $messages_ref->[0];
                %{$header_ref} = (
                    msgid => $header_ref->{msgid},
                    %{ $header_util->extract_header_msgstr( $header_ref->{msgstr} ) },
                );
                $file_lexicon_ref->{gettext_to_maketext}
                    and $self->gettext_to_maketext($messages_ref);
                $file_lexicon_ref->{decode}
                    and $self->_decode_messages($messages_ref);
                $instance->data->{$lexicon_language_key} = {
                    map { ## no critic (ComplexMappings)
                        my $message_ref = $_;
                        my $msg_key = $key_util->join_message_key({(
                            map {
                                $_ => delete $message_ref->{$_};
                            }
                            qw( msgctxt msgid msgid_plural )
                        )});
                        ( $msg_key => $message_ref );
                    } @{$messages_ref}
                };
                $self->logger and $self->logger->(
                    qq{Lexicon "$lexicon_language_key" loaded from file "$filename".},
                    {
                        object => $self,
                        type   => 'debug',
                        event  => 'lexicon,load',
                    },
                );
            }
        }
    }

    return $self;
}

1;

__END__