File Coverage

blib/lib/Locale/TextDomain/OO/Role/DomainAndCategory.pm

Criterion	Covered	Total	%
statement	50	53	94.3
branch	4	8	50.0
condition			n/a
subroutine	12	12	100.0
pod	7	7	100.0
total	73	80	91.2

package Locale::TextDomain::OO::Role::DomainAndCategory; ## no critic (TidyCode)

use strict;
use warnings;
use Carp qw(confess cluck);
use Locale::TextDomain::OO::Translator;
use Moo::Role;

our $VERSION = '1.030';

requires qw(
    category
    domain
);

our ( @domains, @categories ); ## no critic (PackageVars)

sub callback_scope {
    my ( $self, $callback ) = @_;

    local @domains    = @domains;    ## no critic (LocalVars)
    local @categories = @categories; ## no critic (LocalVars)
    my $domain   = $self->domain;
    my $category = $self->category;
    my $translation = $callback->();
    $self->domain($domain);
    $self->category($category);

    return $translation;
}

sub begin_d {
    my ($self, $domain) = @_;

    defined $domain
        or confess 'Domain is not defined';
    push
        @domains,
        $self->domain;
    $self->domain($domain);

    return $self;
}

sub begin_c {
    my ($self, $category) = @_;

    defined $category
        or confess 'Category is not defined';
    push
        @categories,
        $self->category;
    $self->category($category);

    return $self;
}

sub begin_dc {
    my ($self, $domain, $category) = @_;

    $self->begin_d($domain);
    $self->begin_c($category);

    return $self;
}

sub end_d {
    my $self = shift;

    if ( ! @domains ) {
        cluck 'Tried to get the domain from stack but no domain is not stored';
        return $self;
    }
    $self->domain( pop @domains );

    return $self;
}

sub end_c {
    my $self = shift;

    if ( ! @categories ) {
        cluck 'Tried to get the category from stack but no category is stored',
        return $self;
    }
    $self->category( pop @categories );

    return $self;
}

sub end_dc {
    my $self = shift;

    $self->end_d;
    $self->end_c;

    return $self;
}

1;

__END__