File Coverage

blib/lib/Locale/TextDomain/IfEnv.pm

Criterion	Covered	Total	%
statement	33	36	91.6
branch	6	10	60.0
condition			n/a
subroutine	15	15	100.0
pod	0	4	0.0
total	54	65	83.0

package Locale::TextDomain::IfEnv;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2019-12-26'; # DATE
our $DIST = 'Locale-TextDomain-IfEnv'; # DIST
our $VERSION = '0.001'; # VERSION

#use strict 'subs', 'vars';
#use warnings;

sub __expand($@) {
    my ($translation, %args) = @_;
    my $re = join '|', map { quotemeta $_ } keys %args;
    $translation =~ s/\{($re)\}/defined $args{$1} ? $args{$1} : "{$1}"/ge;
    $translation;
}

# plain string
sub __($) {
    $_[0];
}

# interpolation
sub __x($@) {
    goto &__expand;
}

# plural
sub __n($$$) {
    my ($msgid, $msgid_plural, $count) = @_;
    $count > 1 ? $msgid_plural : $msgid;
}

# plural + interpolation
sub __nx($$$@) {
    my ($msgid, $msgid_plural, $count, %args) = @_;
    __expand($count > 1 ? $msgid_plural : $msgid, %args);
}

# alias for __nx
sub __xn($$$@) {
    goto &__nx;
}

# context
sub __p($$) {
    $_[1];
}

# context + interpolation
sub __px($$@) {
    my $context = shift;
    goto &__x;
}

# context + plural
sub __np($$$$) {
    my $context = shift;
    goto &__n;
}

# context + plural + interpolation
sub __npx($$$$@) {
    my $context = shift;
    goto &__nx;
}

# Dummy functions for string marking.
sub N__($) {
    return shift;
}

sub N__n($$$) {
    return @_;
}

sub N__p($$) {
    return @_;
}

sub N__np($$$$) {
    return @_;
}

sub import {
    my $class = shift;
    local $Locale::TextDomain::IfEnv::textdomain = shift;
    local @Locale::TextDomain::IfEnv::search_dirs = @_;

    my $caller = caller;

    if ($ENV{PERL_LOCALE_TEXTDOMAIN_IFENV}) {
        require Locale::TextDomain;
        eval "package $caller; use Locale::TextDomain \$Locale::TextDomain::IfEnv::textdomain, \@Locale::TextDomain::IfEnv::search_dirs;";
        die if $@;
    } else {
        for (qw(__ __x __n __nx __xn __p __px __np __npx
                N__ N__n N__p N__np)) {
            *{"$caller\::$_"} = \&{$_};
        }
    }
}

1;
# ABSTRACT: Enable translation only when environment variable flag is true

__END__