File Coverage

blib/lib/Locale/Maketext/Extract/Plugin/YAML.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	5	6	83.3
condition	9	15	60.0
subroutine	12	12	100.0
pod	2	2	100.0
total	81	88	92.0

package Locale::Maketext::Extract::Plugin::YAML;
$Locale::Maketext::Extract::Plugin::YAML::VERSION = '1.00';
use strict;
use base qw(Locale::Maketext::Extract::Plugin::Base);

# ABSTRACT: YAML format parser


sub file_types {
    return qw( yaml yml conf );
}

sub extract {
    my $self = shift;
    my $data = shift;

    my $y = Locale::Maketext::Extract::Plugin::YAML::Extractor->new();
    $y->load($data);

    foreach my $entry ( @{ $y->found } ) {
        $self->add_entry(@$entry);
    }

}

package Locale::Maketext::Extract::Plugin::YAML::Extractor;
$Locale::Maketext::Extract::Plugin::YAML::Extractor::VERSION = '1.00';
use base qw(YAML::Loader);

#===================================
sub new {
#===================================
    my $class = shift;
    my $self  = $class->SUPER::new(@_);
    $self->{found} = [];
    return $self;
}

#===================================
sub check_scalar {
#===================================
    my $self = shift;
    my $node = $_[0];
    if ( defined $node && !ref $node && $node =~ /^__?(["'])(.+)\1$/s ) {
        my $string = $2;
        my $line   = $_[1];
        push @{ $self->{found} }, [ $string, $line ];
    }
    return $node;
}

sub _parse_node {
    my $self = shift;
    my $line = $self->{_start_line}
        ||= length( $self->preface ) ? $self->line - 1 : $self->line;
    my $node = $self->SUPER::_parse_node(@_);
    $self->{start_line} = 0;
    return $self->check_scalar( $node, $line );
}

sub _parse_inline_seq {
    my $self = shift;
    my $line = $self->{_start_line} ||= $self->line;
    my $node = $self->SUPER::_parse_inline_seq(@_);
    foreach (@$node) {
        $self->check_scalar( $_, $line );
    }
    $self->{start_line} = 0;
    return $node;
}

sub _parse_inline_mapping {
    my $self = shift;
    my $line = $self->{_start_line} ||= $self->line;
    my $node = $self->SUPER::_parse_inline_mapping(@_);
    foreach ( values %$node ) {
        $self->check_scalar( $_, $line );
    }
    $self->{start_line} = 0;
    return $node;
}

#===================================
sub _parse_next_line {
#===================================
    my $self = shift;
    $self->{_start_line} = $self->line
        if $_[0] == YAML::Loader::COLLECTION;
    $self->SUPER::_parse_next_line(@_);
}

sub found {
    my $self = shift;
    return $self->{found};
}


1;

__END__