File Coverage

blib/lib/List/Rotation.pm

Criterion	Covered	Total	%
statement	42	46	91.3
branch	2	4	50.0
condition			n/a
subroutine	14	14	100.0
pod			n/a
total	58	64	90.6

package List::Rotation;
use 5.006;
our $VERSION = '1.010';

package List::Rotation::Cycle;
use strict;
use warnings;

use Memoize;
memoize('new');

sub new {
    my $class = shift;

    do {
        require Carp;
        Carp::croak ("Incorrect number of arguments; must be >= 1.");
    } unless 1 <= @_;
    my $r_values = [ @_ ];
    my $position = undef;
    my $length = @$r_values;

    my $method = {
        _next => sub {
            $position = defined $position ? ++$position : 0;
            my $i = $position % $length;
            return $r_values->[$i];
        },
        _prev => sub {
            $position = defined $position ? --$position : -1;
            my $i = $position % $length;
            return $r_values->[$i];
        },
        _curr => sub {
            return unless defined $position;
            my $i = $position % $length;
            return $r_values->[$i];
        },
        _reset => sub {
            $position = undef;
        },
    };

    my $closure = sub {
        my $call = shift;
        &{ $method->{$call} };
    };

    bless $closure, $class;
}

sub next  { my $self = shift; &{ $self }( '_next'  ); }
sub prev  { my $self = shift; &{ $self }( '_prev'  ); }
sub curr  { my $self = shift; &{ $self }( '_curr'  ); }
sub reset { my $self = shift; &{ $self }( '_reset' ); }

#-------------------------------------------------------------------------------

package List::Rotation::Alternate;

use strict;

use vars qw( @ISA );
@ISA = qw(List::Rotation::Cycle);

sub new {
    my $class = shift;

    do {
        require Carp;
        Carp::croak ("Incorrect number of arguments; must be <2>.");
    } unless 2 == @_;

    $class->SUPER::new(@_);
}

#-------------------------------------------------------------------------------

package List::Rotation::Toggle;

use strict;

use vars qw( @ISA );
@ISA = qw(List::Rotation::Alternate);

sub new {
    my $class = shift;

    do {
        require Carp;
        Carp::croak ("No arguments accepted.");
    } unless 0 == @_;

    $class->SUPER::new( 1 == 1, 0 == 1 );
}

#-------------------------------------------------------------------------------

1;


__END__