File Coverage

blib/lib/List/Range.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	16	18	88.8
condition			n/a
subroutine	12	12	100.0
pod	4	5	80.0
total	77	80	96.2

package List::Range;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.01";

use Class::Accessor::Lite ro => [qw/name lower upper/];
use overload '@{}'    => sub { [shift->all] },
             fallback => 1;

use Carp qw/croak/;

sub new {
    my ($class, %args) = @_;
    my $self = bless {
        lower => '-Inf',
        upper => '+Inf',
        name  => '',
        %args,
    } => $class;
    $self->{lower} <= $self->{upper}
        or croak "Cannot make a range by $self->{lower}..$self->{upper}";
    return $self;
}

sub includes {
    my $self = shift;
    if (ref $_[0] eq 'CODE') {
        my $code = shift;

        my $tmp; # for preformance
        return grep {
            $tmp = $code->($_);
            $self->{lower} <= $tmp && $tmp <= $self->{upper}
        } @_;
    }
    return grep { $self->{lower} <= $_ && $_ <= $self->{upper} } @_;
}

sub excludes {
    my $self = shift;
    if (ref $_[0] eq 'CODE') {
        my $code = shift;
        my $tmp; # for preformance
        return grep {
            $tmp = $code->($_);
            $tmp < $self->{lower} || $self->{upper} < $tmp
        } @_;
    }
    return grep { $_ < $self->{lower} || $self->{upper} < $_ } @_;
}

# for duck typing
sub ranges { [shift] }

sub all {
    my $self = shift;
    croak 'lower is infinit' if $self->lower == '-Inf';
    croak 'upper is infinit' if $self->upper == '+Inf';
    return ($self->lower..$self->upper);
}

1;
__END__