File Coverage

blib/lib/List/DoubleLinked/Iterator.pm

Criterion	Covered	Total	%
statement	55	55	100.0
branch	3	6	50.0
condition			n/a
subroutine	14	14	100.0
pod	5	6	83.3
total	77	81	95.0

package List::DoubleLinked::Iterator;
$List::DoubleLinked::Iterator::VERSION = '0.005';
use strict;
use warnings FATAL => 'all';

use Carp qw/croak/;
use Scalar::Util 'weaken';
use namespace::clean 0.20;

use overload
	'==' => sub {
		my ($left, $right, $switch) = @_;
		return $left->[0] == $right->[0];
	},
	'!=' => sub {
		my ($left, $right, $switch) = @_;
		return $left->[0] != $right->[0];
	},
	fallback => 1;

sub new {
	my ($class, $node) = @_;
	my $self = bless [ $node ], $class;
	weaken $self->[0];
	Internals::SvREADONLY(@{$self}, 1);
	return $self;
}

sub get {
	my $self = shift;
	return if not defined $self->[0];
	return $self->[0]{item};
}

## no critic (Subroutines::ProhibitBuiltinHomonyms)

sub next {
	my $self = shift;
	my $node  = $self->[0];
	croak 'Node no longer exists' if not defined $node;
	return __PACKAGE__->new($node->{next});
}

sub previous {
	my $self = shift;
	my $node  = $self->[0];
	croak 'Node no longer exists' if not defined $node;
	return __PACKAGE__->new($node->{prev});
}

sub insert_before {
	my ($self, @items) = @_;
	my $node  = $self->[0];
	for my $item (reverse @items) {
		my $new_node = {
			item => $item,
			prev => $node->{prev},
			next => $node,
		};
		$node->{prev}{next} = $new_node;
		$node->{prev} = $new_node;

		$node = $new_node;
	}
	return;
}

sub insert_after {
	my ($self, @items) = @_;
	my $node  = $self->[0];
	for my $item (@items) {
		my $new_node = {
			item => $item,
			prev => $node,
			next => $node->{next},
		};
		$node->{next}{prev} = $new_node;
		$node->{next} = $new_node;

		$node = $new_node;
	}
	return;
}

# ABSTRACT: Double Linked List Iterators

1;

__END__