File Coverage

blib/lib/List/AssignRef.pm

Criterion	Covered	Total	%
statement	35	36	97.2
branch	7	14	50.0
condition			n/a
subroutine	13	14	92.8
pod	1	1	100.0
total	56	65	86.1

package List::AssignRef;

use 5.006;
use strict;
use warnings;
use LV qw( lvalue );
use Carp qw( confess );
use Scalar::Util qw( reftype );

use constant {
	SCALAR   => 'SCALAR',
	ARRAY    => 'ARRAY',
	HASH     => 'HASH',
};

use constant {
	ERR_UNSUPPORTED => "Unsupported reference type: %s",
	ERR_MISMATCH    => "Reference type mismatch: %s vs %s",
};

BEGIN {
	$List::AssignRef::AUTHORITY = 'cpan:TOBYINK';
	$List::AssignRef::VERSION   = '0.005';
}

use Exporter::Shiny our @EXPORT = qw( deref );

sub _confessf
{
	my $fmt = shift;
	confess sprintf $fmt, @_;
}

sub deref (\[$@%]) :lvalue
{
	my $given = shift;
	lvalue get => sub {
		reftype($given) eq SCALAR ? $$given :
		reftype($given) eq ARRAY  ? @$given :
		reftype($given) eq HASH   ? %$given :
		_confessf(ERR_UNSUPPORTED, reftype($given));
	},
	set => sub {
		my $assign = shift;
		reftype($given) eq reftype($assign)
			or _confessf(ERR_MISMATCH, reftype($given), reftype($assign));
		reftype($given) eq SCALAR ? ($$given = $$assign):
		reftype($given) eq ARRAY  ? (@$given = @$assign):
		reftype($given) eq HASH   ? (%$given = %$assign):
		_confessf(ERR_UNSUPPORTED, reftype($given));
	}
}

1;

__END__