File Coverage

blib/lib/Linux/Statm/Tiny.pm

Criterion	Covered	Total	%
statement	26	26	100.0
branch	1	2	50.0
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	35	36	97.2

package Linux::Statm::Tiny;

use v5.10.1;

use Moo;
use MooX::Aliases;

use Fcntl qw/ O_RDONLY /;
use POSIX qw/ ceil /;
use Types::Standard qw/ ArrayRef Int /;

our $VERSION = '0.0601';

# ABSTRACT: simple access to Linux /proc/../statm


has pid => (
    is      => 'lazy',
    isa     => Int,
    default => sub { $$ },
    );


my $PageSize;

has page_size => (
    is      => 'lazy',
    isa     => Int,
    default => sub {
        $PageSize //= `getconf PAGE_SIZE`
            or die "Unable to run getconf PAGE_SIZE: $!";
        $PageSize += 0;
        },
    init_arg => undef,
    );


has statm => (
    is       => 'lazy',
    isa      => ArrayRef[Int],
    writer   => 'refresh',
    init_arg => undef,
    );

sub _build_statm {
    my ($self) = @_;
    my $pid = $self->pid;
    sysopen( my $fh, "/proc/${pid}/statm", O_RDONLY )
        or die "Unable to open /proc/${pid}/statm: $!";
    chomp(my $raw = <$fh>);
    close $fh;
    [ split / /, $raw ];
    }


my %stats = (
    size     => 0,
    resident => 1,
    share    => 2,
    text     => 3,
    lib      => 4,
    data     => 5,
    dt       => 6,
    );

my %aliases = (
    size     => 'vsz',
    resident => 'rss',
    );

my %alts = (       # page_size multipliers
    bytes    => 1,
    kb       => 1024,
    mb       => 1048576,
    );

my @attrs;

foreach my $attr (keys %stats) {

    my @aliases = ( "${attr}_pages" );
    push @aliases, ( $aliases{$attr}, $aliases{$attr} . '_pages' )
        if $aliases{$attr};

    has $attr => (
        is       => 'lazy',
        isa      => Int,
        default  => sub { shift->statm->[$stats{$attr}] },
        init_arg => undef,
        alias    => \@aliases,
        clearer  => "_refresh_${attr}",
        );

    push @attrs, $attr;

    foreach my $alt (keys %alts) {
        has "${attr}_${alt}" => (
            is       => 'lazy',
            isa      => Int,
            default  => sub { my $self = shift;
                              ceil($self->$attr * $self->page_size / $alts{$alt});
                              },
            init_arg => undef,
            clearer  => "_refresh_${attr}_${alt}",
            $aliases{$attr} ? ( alias => $aliases{$attr} . "_${alt}" ) : ( ),
            );

        push @attrs, "${attr}_${alt}";
        }

    }

around refresh => sub {
    my ($next, $self) = @_;
    $self->$next( $self->_build_statm );
    foreach my $attr (@attrs) {
        my $meth = "_refresh_${attr}";
        $self->$meth;
        }
    };



use namespace::autoclean 0.16;

1;

__END__