File Coverage

blib/lib/Lingua/LO/Transform/Romanize.pm

Criterion	Covered	Total	%
statement	40	43	93.0
branch	2	6	33.3
condition	3	6	50.0
subroutine	9	10	90.0
pod	3	3	100.0
total	57	68	83.8

package Lingua::LO::Transform::Romanize;
use strict;
use warnings;
use 5.012000;
use utf8;
use version 0.77; our $VERSION = version->declare('v0.0.1');
use Carp;
use Lingua::LO::Transform::Syllables;

=encoding UTF-8

=head1 NAME

Lingua::LO::Transform::Romanize - Romanize Lao syllables

=head1 FUNCTION

This s a factory class for Lingua::LO::Transform::Romanize::*. Currently there
is only L but other variants are
planned.

=head1 SYNOPSIS

    my $o = Lingua::LO::Transform::Romanize->new(
        variant => 'PCGN',
        hyphenate => 1,
    );

=cut

=head1 METHODS

=head2 new

See L on how to use the constructor. Arguments supported are:

=over 4

=item C: standard according to which to romanize. "PCGN" is the only
one currently implemented.

=item C: separate runs of Lao syllables with hyphens if true.
Otherwise, blanks are used.

=back

=cut

sub new {
    my ($class, %args) = @_;
    my $variant = delete $args{variant} or confess("`variant' arg missing");
    my $hyphenate = delete $args{hyphenate};

    my $subclass = __PACKAGE__ . "::$variant";
    (my $module = $subclass) =~ s!::!/!g;
    require "$module.pm";

    my $self = $subclass->new(%args);
    $self->{hyphenate} = $hyphenate;
    return $self;
}

=head2 romanize

    romanize( $text )

Return the romanization of C<$text> according to the standard passed to the
constructor. Text is split up by
L; Lao syllables are processed
and everything else is passed through unchanged save for possible conversion of
combining characters to a canonically equivalent form in
L.

=cut

sub romanize {
    my ($self, $text) = @_;
    my $result = '';
    my $sep_char = $self->{hyphenate} ? '-' : ' ';

    my @frags = Lingua::LO::Transform::Syllables->new( text => $text )->get_fragments;
    while(@frags) {
        my @lao;
        push @lao, shift @frags while @frags and $frags[0]->{is_lao};
        $result .= join($sep_char, map { $self->romanize_syllable( $_->{text} ) } @lao);
        $result .= (shift @frags)->{text} while @frags and not $frags[0]->{is_lao};
    }
    return $result;
}

=head2 romanize_syllable

    romanize_syllable( $syllable )

Return the romanization of a single C<$syllable> according to the standard passed to the
constructor. This is a virtual method that must be implemented by subclasses.

=cut

sub romanize_syllable {
    my $self = shift;
    ref $self or die "romanize_syllable is not a class method";
    die ref($self) . " must implement romanize_syllable()";
}

1;