File Coverage

blib/lib/Lingua/JA/Expand/DataSource/YahooSearch.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Lingua::JA::Expand::DataSource::YahooSearch;
use strict;
use warnings;
use base qw(Lingua::JA::Expand::DataSource);
use Carp;
use LWP::UserAgent;
use XML::LibXML::Simple;

__PACKAGE__->mk_accessors($_) for qw(_xml);

sub new {
    my $class = shift;
    my $self  = $class->SUPER::new(@_);
    $self->_prepare;
    return $self;
}

sub extract_text {
    my $self     = shift;
    my $word_ref = shift;
    my $xml      = $self->raw_data($word_ref);
    if ( my $error_msg = $xml->{'Error'}->{'Message'} ) {
        $error_msg =~ s/\n//g;
        carp("Yahoo API returns error message : $error_msg") and return;
    }
    my $text;
    if ( ref $xml->{ResultSet}->{Result} eq 'ARRAY' ) {
        my @items = @{ $xml->{ResultSet}->{Result} };
        for my $item (@items) {
            $text .= $item->{Title}   if $item->{Title};
            $text .= ' ';
            $text .= $item->{Summary} if $item->{Summary};
        }
    }
    return \$text;
}

sub raw_data {
    my $self = shift;
    if ( @_ > 0 || !$self->_xml ) {
        my $word_ref = shift;
        $$word_ref =~ s/([^\w ])/'%'.unpack('H2', $1)/eg;
        $$word_ref =~ tr/ /+/;
        my $url = $self->{url} . $$word_ref;
        my $req = HTTP::Request->new( GET => $url );
        my $res = $self->{user_agent}->request($req);
        my $xml = XML::LibXML::Simple::XMLin( $res->content, keepRoot => 1, );
        $self->_xml($xml);
    }
    else {
        return $self->_xml;
    }
}

sub _prepare {
    my $self                 = shift;
    my %LWP_UserAgent_config = ();
    if ( ref $self->config->{LWP_UserAgent} eq 'HASH' ) {
        %LWP_UserAgent_config = %{ $self->config->{LWP_UserAgent} };
    }
    $self->{user_agent} = LWP::UserAgent->new(%LWP_UserAgent_config);
    my $yahoo_api_appid = $self->config->{yahoo_api_appid};
    croak("you must set your own 'yahoo_api_app_id'") if !$yahoo_api_appid;

    if ( $self->config->{yahoo_api_premium} ) {
        $self->{url}
            = 'http://search.yahooapis.jp/PremiumWebSearchService/V1/webSearch?appid='
            . $yahoo_api_appid
            . '&results=20&adult_ok=1&query=';
    }
    else {
        $self->{url}
            = 'http://search.yahooapis.jp/WebSearchService/V2/webSearch?appid='
            . $yahoo_api_appid
            . '&results=20&adult_ok=1&query=';
    }
}

1;

__END__