File Coverage

blib/lib/Lazy/Iterator.pm

Criterion	Covered	Total	%
statement	38	48	79.1
branch	11	16	68.7
condition	1	3	33.3
subroutine	9	12	75.0
pod	5	5	100.0
total	64	84	76.1

use strict;
use warnings;

package Lazy::Iterator;
$Lazy::Iterator::VERSION = '0.004';
#ABSTRACT: Objects encapsulating a set of lazy evaluation functions.


use Carp qw/ croak /;
use Scalar::Util qw/ blessed /;

use constant SCALAR_DEFER => eval { require Scalar::Defer; 1 };

sub _isa { defined blessed $_[0] and $_[0]->isa($_[1]); }


sub new {
  my ($class, $source) = @_;

  if (SCALAR_DEFER and _isa($source, 0)) {
    my $sd = $source;
    $source = sub { Scalar::Defer::force $sd };
  }

  croak "Not a CODE reference: $source" if ref $source ne 'CODE';

  return bless {code => $source, exhausted => 0}, $class;
}


sub exhausted {
  my $self = shift;

  unshift @{ $self->{get} }, $self->get();

  return $self->{exhausted};
}


sub get {
  my $self = shift;

  return shift @{ $self->{get} } if @{ $self->{get} || [] };

  return undef if $self->{exhausted};

  my $ret = $self->{code}->();
  $self->{exhausted} = 1 if not defined $ret;

  return $ret;
}


sub get_all {
  my $self = shift;

  my @res;
  while (defined(my $get = $self->get())) { push @res, $get; }

  return @res;
}


sub unget {
  my $self = shift;
  my $value = shift;

  croak "Can't unget an undefined value." if not defined $value;

  unshift @{ $self->{get} }, $value;

  return $self;
}

1;

__END__