File Coverage

blib/lib/Lazy/Bool.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	6	6	100.0
condition	2	3	66.6
subroutine	19	19	100.0
pod	4	4	100.0
total	71	72	98.6

package Lazy::Bool;

use 5.010000;
use strict;
use warnings;
use Exporter 'import';

our $VERSION   = '0.06';
our @EXPORT_OK = qw(lzb);

sub lzb(&) {
    my $code = shift;
    __PACKAGE__->new($code);
}

sub new {
    my ( $type, $code ) = @_;
    my $klass = ref($type) || $type;
    my $ref = ( ref($code) eq 'CODE' ) ? $code : sub { $code };

    bless $ref => $klass;
}

sub true {
    shift->new( sub { 1 } );
}

sub false {
    shift->new( sub { 0 } );
}

use overload
  'bool' => \&_to_bool,
  '&'    => \&_lazy_and,
  '|'    => \&_lazy_or,
  '!'    => \&_lazy_neg;

sub _to_bool {
    shift->();
}

sub _lazy_and {
    my ( $a, $b ) = @_;

    $a->new(
        sub {
            my $real = $a->_to_bool;

            return $real unless $real;

            $real & $b;
        }
    );
}

sub _lazy_or {
    my ( $a, $b ) = @_;

    $a->new(
        sub {
            my $real = $a->_to_bool;

            return $real if $real;

            $real | $b;
        }
    );
}

sub _lazy_neg {
    my $a = shift;
    $a->new(
        sub {
            !$a->_to_bool;
        }
    );
}

1;
__END__