File Coverage

blib/lib/LWP/UserAgent/ProgressBar.pm

Criterion	Covered	Total	%
statement	47	48	97.9
branch	8	12	66.6
condition			n/a
subroutine	9	9	100.0
pod	2	2	100.0
total	66	71	92.9

use 5.008;
use strict;
use warnings;

package LWP::UserAgent::ProgressBar;
our $VERSION = '1.100810';
# ABSTRACT: An LWP user agent that can display a progress bar
use Term::ProgressBar;
use base 'LWP::UserAgent';

sub post_with_progress {
    my ($self, $url, $form, %args) = @_;
    $self->_request_with_progress('post', $url, $form, %args);
}

sub get_with_progress {
    my ($self, $url, %args) = @_;
    $self->_request_with_progress('get', $url, undef, %args);
}

sub _request_with_progress {
    my ($self, $req, $url, $form, %args) = @_;

    # don't buffer the prints to make the status update
    local $| = 1;
    my $bar_name;
    if (defined $args{bar_name}) {
        $bar_name = $args{bar_name};
        delete $args{bar_name};
    }
    my $progress = Term::ProgressBar->new(
        {   count => 1024,
            (defined $bar_name ? (name => $bar_name) : ()),
            ETA => 'linear',
        }
    );
    $progress->minor(0);              # turns off the floating asterisks.
    $progress->max_update_rate(1);    # only relevant when ETA is used.
    my $did_set_target = 0;
    my $received_size  = 0;
    my $next_update    = 0;
    my $content        = '';
    delete $args{$_} for qw(:content_cb :read_size_hint);
    $args{':content_cb'} = sub {
        my ($data, $cb_response, $protocol) = @_;
        unless ($did_set_target) {
            if (my $content_length = $cb_response->content_length) {
                $progress->target($content_length);
                $did_set_target = 1;
            } else {
                $progress->target($received_size + 2 * length $data);
            }
        }
        $received_size += length $data;
        $content .= $data;
        $next_update = $progress->update($received_size)
          if $received_size >= $next_update;
    };
    $args{':read_size_hint'} = 8192;
    my $response =
      $self->$req($url, $req eq 'get' ? (%$form, %args) : ($form, %args));
    print "\n";
    $response->content($content);
    $response;
}
1;


__END__