File Coverage

blib/lib/Kelp/Module/RDBO.pm

Criterion	Covered	Total	%
statement	42	43	97.6
branch	9	12	75.0
condition	4	6	66.6
subroutine	10	11	90.9
pod	1	1	100.0
total	66	73	90.4

package Kelp::Module::RDBO;
use Kelp::Base 'Kelp::Module';
use Rose::DB;
use Rose::DB::Object;
use Plack::Util;
use Class::Inspector;
use Module::Find;

our $VERSION = 0.106;

sub build {
    my ( $self, %args ) = @_;

    # Set default prefix to AppName::DB
    $args{prefix} //= ref( $self->app ) . '::DB';

    my @source =
      ref( $args{source} ) eq 'ARRAY'
      ? @{ $args{source} }
      : ( $args{source} );

    Rose::DB->register_db(%$_) for @source;
    Rose::DB->default_type( $args{default_type} )     if $args{default_type};
    Rose::DB->default_domain( $args{default_domain} ) if $args{default_domain};

    # Insert the app into Rose::DB::Object
    no strict 'refs';
    *{"Rose::DB::Object::app"} = sub { $self->app };

    # Preload all modules, if requested
    if ( $ENV{KELP_RDBO_PRELOAD} || $args{preload} ) {
        useall $args{prefix};
    }

    $self->register(
        rdb  => Rose::DB->new,
        rdbo => sub {
            my ( $app, $name ) = @_;

            # Load the class
            my $full_name = $args{prefix} . '::' . $name;
            my $class =
              Class::Inspector->loaded($full_name)
              ? $full_name
              : Plack::Util::load_class($full_name);

            # Insert an init_db method, if none found
            my $glob = "${class}::init_db";
            *{$glob} = sub { $app->rdb }
              unless ( *{$glob}{CODE} );

            # Return class only
            return $class;
        }
    );
}

1;

__END__