File Coverage

blib/lib/Jonk/Job.pm

Criterion	Covered	Total	%
statement	9	43	20.9
branch	0	14	0.0
condition	0	6	0.0
subroutine	3	20	15.0
pod	12	16	75.0
total	24	99	24.2

package Jonk::Job;
use strict;
use warnings;
use Carp ();

sub new {
    my ($class, $jonk, $job) =@_;
    bless {
        job        => $job,
        _jonk      => $jonk,
        _completed => 0,
        _failed    => 0,
        _aborted   => 0,
    }, $class;
}

sub completed {
    my $self = shift;

    Carp::croak 'job is already failed.'  if $self->is_failed;
    Carp::croak 'job is already aborted.' if $self->is_aborted;

    $self->{_completed} = 1;
    $self->{_jonk}->_delete($self->id);
}

sub failed {
    my ($self, $opt) = @_;

    Carp::croak 'job is already complated.' if $self->is_completed;
    Carp::croak 'job is already aborted.'   if $self->is_aborted;

    $self->{_failed} = 1;
    $self->{_jonk}->_failed(
        $self->id => $opt
    );
}

sub aborted {
    my $self = shift;

    Carp::croak 'job is already complated.' if $self->is_completed;
    Carp::croak 'job is already failed.'    if $self->is_failed;

    $self->{_aborted} = 1;
    $self->{_jonk}->_delete($self->id);
}

sub id            { $_[0]->{job}->{id}            }
sub func          { $_[0]->{job}->{func}          }
sub raw_arg       { $_[0]->{job}->{arg}           }
sub arg {
    my $self = shift;
    $self->{_jonk}->{functions}->{$self->func}->{deserializer}->($self->{job}->{arg});
}
sub enqueue_time  { $_[0]->{job}->{enqueue_time}  }
sub grabbed_until { $_[0]->{job}->{grabbed_until} }
sub retry_cnt     { $_[0]->{job}->{retry_cnt}     }
sub run_after     { $_[0]->{job}->{run_after}     }
sub priority      { $_[0]->{job}->{priority}      }

sub is_completed { $_[0]->{_completed} }
sub is_failed    { $_[0]->{_failed}    }
sub is_aborted   { $_[0]->{_aborted}   }

sub DESTROY {
    my $self = shift;
    unless ($self->is_completed or $self->is_aborted or $self->is_failed) {
        Carp::cluck "job is not (complete|fail|abor)ed. this job auto failed.";
        $self->failed;
    }
}

1;

__END__