File Coverage

blib/lib/JavaScript/QuickJS.pm

Criterion	Covered	Total	%
statement	19	19	100.0
branch	4	4	100.0
condition			n/a
subroutine	7	7	100.0
pod	2	2	100.0
total	32	32	100.0

package JavaScript::QuickJS;

use strict;
use warnings;

=encoding utf-8

=head1 NAME

JavaScript::QuickJS - Run JavaScript via L in Perl

=head1 SYNOPSIS

Quick and dirty …

    my $val = JavaScript::QuickJS->new()->eval( q<
        let foo = "bar";
        [ "The", "last", "value", "is", "returned." ];
    > );

… or, something a bit fancier:

    my $js = JavaScript::QuickJS->new()->std()->helpers();

    $js->eval_module( q/
        import * as std from 'std';

        for (const [key, value] of Object.entries(std.getenviron())) {
            console.log(key, value);
        }
    / );

=head1 DESCRIPTION

This library embeds Fabrice Bellard’s L
engine into a Perl XS module. You can thus run JavaScript
(L specification) directly in your
Perl programs.

This distribution includes all needed C code; unlike with most XS modules
that interface with C libraries, you don’t need QuickJS pre-installed on
your system.

=cut

# ----------------------------------------------------------------------

use XSLoader;

our $VERSION = '0.16_92';

XSLoader::load( __PACKAGE__, $VERSION );

# ----------------------------------------------------------------------

=head1 METHODS

=head2 $obj = I->new( %CONFIG_OPTS )

Instantiates I. %CONFIG_OPTS have the same effect as in
C below.

=cut

sub new {
    my ($class, %opts) = @_;

    my $self = $class->_new();

    return %opts ? $self->configure(%opts) : $self;
}

=head2 $obj = I->configure( %OPTS )

Tunes the QuickJS interpreter. Returns I.

%OPTS are any of:

=over

=item * C

=item * C

=item * C

=back

For more information on these, see QuickJS itself.

=cut

sub configure {
    my ($self, %opts) = @_;

    my ($stack, $memlimit, $gc_threshold) = delete @opts{'max_stack_size', 'memory_limit', 'gc_threshold'};

    if (my @extra = sort keys %opts) {
        Carp::croak("Unknown: @extra");
    }

    return $self->_configure($stack, $memlimit, $gc_threshold);
}

#----------------------------------------------------------------------

=head2 $obj = I->set_globals( NAME1 => VALUE1, .. )

Sets 1 or more globals in I. See below for details on type conversions
from Perl to JavaScript.

Returns I.

=head2 $obj = I->helpers()

Defines QuickJS’s “helpers”, e.g., C.

Returns I.

=head2 $obj = I->std()

Enables (but does I import) QuickJS’s C module.
See L above for example usage.

Returns I.

=head2 $obj = I->os()

Like C but for QuickJS’s C module.

=head2 $VALUE = I->eval( $JS_CODE )

Comparable to running C. Returns $JS_CODE’s last value;
see below for details on type conversions from JavaScript to Perl.

Untrapped exceptions in JavaScript will be rethrown as Perl exceptions.

$JS_CODE is a I string.

=head2 $obj = I->eval_module( $JS_CODE )

Runs $JS_CODE as a module, which enables ES6 module syntax.
Note that no values can be returned directly in this mode of execution.

Returns I.

=head2 $obj = I->await()

Blocks until all of I’s pending work (if any) is complete.

For example, if you C some code that creates a promise, call
this to wait for that promise to complete.

Returns I.

=head2 $obj = I->set_module_base( $PATH )

Sets a base path (a byte string) for ES6 module imports.

Returns I.

=head2 $obj = I->unset_module_base()

Restores QuickJS’s default directory for ES6 module imports
(as of this writing, it’s the process’s current directory).

Returns I.

=cut

# ----------------------------------------------------------------------

=head1 TYPE CONVERSION: JAVASCRIPT → PERL

This module converts returned values from JavaScript thus:

=over

=item * JS string primitives become I strings in Perl.

=item * JS number & boolean primitives become corresponding Perl values.

=item * JS null & undefined become Perl undef.

=item * JS objects …

=over

=item * Arrays become Perl array references.

=item * “Plain” objects become Perl hash references.

=item * Function, RegExp, and Date objects become Perl
L, L,
and L objects, respectively.

=item * Behaviour is B for other object types.

=back

=back

=head1 TYPE CONVERSION: PERL → JAVASCRIPT

Generally speaking, it’s the inverse of JS → Perl:

=over

=item * Perl strings, numbers, & booleans become corresponding JavaScript
primitives.

B Perl versions before 5.36 don’t reliably distinguish “numeric
strings” from “numbers”. If your perl predates 5.36, typecast accordingly
to prevent your Perl “number” from becoming a JavaScript string. (Even in
5.36 and later it’s still a good idea.)

=item * Perl undef becomes JS null.

=item * Unblessed array & hash references become JavaScript arrays and
“plain” objects.

=item * L booleans become JavaScript booleans.

=item * Perl code references become JavaScript functions.

=item * Perl L, L,
and L objects become their original
JavaScript objects.

=item * Anything else triggers an exception.

=back

=head1 MEMORY HANDLING NOTES

If any instance of a class of this distribution is DESTROY()ed at Perl’s
global destruction, we assume that this is a memory leak, and a warning is
thrown. To prevent this, avoid circular references, and clean up all global
instances.

Callbacks make that tricky. When you give a JavaScript function to Perl,
that Perl object holds a reference to the QuickJS context. Only once that
object is Ced do we release that QuickJS context reference.

Consider the following:

    my $return;

    $js->set_globals(  __return => sub { $return = shift; () } );

    $js->eval('__return( a => a )');

This sets $return to be a L instance. That
object holds a reference to $js. $js also stores C<__return()>,
which is a Perl code reference that closes around $return. Thus, we have
a reference cycle: $return refers to $js, and $js refers to $return. Those
two values will thus leak, and you’ll see a warning about it at Perl’s
global destruction time.

To break the reference cycle, just do:

    undef $return;

… once you’re done with that variable.

You I have thought you could instead do:

    $js->set_globals( __return => undef )

… but that doesn’t work because $js holds a reference to all Perl code
references it B receives. This is because QuickJS, unlike Perl,
doesn’t expose object destructors (C in Perl), so there’s no
good way to release that reference to the code reference.

=head1 CHARACTER ENCODING NOTES

QuickJS (like all JS engines) assumes its strings are text. Since Perl
can’t distinguish text from bytes, though, it’s possible to convert
Perl byte strings to JavaScript strings. It often yields a reasonable
result, but not always.

One place where this falls over, though, is ES6 modules. QuickJS, when
it loads an ES6 module, decodes that module’s string literals to characters.
Thus, if you pass in byte strings from Perl, QuickJS will treat your
Perl byte strings’ code points as character code points, and when you
combine those code points with those from your ES6 module you may
get mangled output.

Another place that may create trouble is if your argument to C
or C (above) contains JSON. Perl’s popular JSON encoders
output byte strings by default, but as noted above, C and
C need I strings. So either configure your
JSON encoder to output characters, or decode JSON bytes to characters
before calling C/C.

For best results, I interact with QuickJS via I
strings, and double-check that you’re doing it that way consistently.

=head1 NUMERIC PRECISION

Note the following if you expect to deal with “large” numbers:

=over

=item * JavaScript’s numeric-precision limits apply. (cf.
L.)

=item * Perl’s stringification of numbers may be I precise than
JavaScript’s storage of those numbers, or even than Perl’s own storage.
For example, in Perl 5.34 C prints C<1e+15>.

To counteract this loss of precision, add 0 to Perl’s numeric scalars
(e.g., C); this will encourage Perl to store
numbers as integers when possible, which fixes this precision problem.

=item * Long-double and quad-math perls may lose precision when converting
numbers to/from JavaScript. To see if this affects your perl—which, if
you’re unsure, it probably doesn’t—run C, and see if that perl’s
compile-time options mention long doubles or quad math.

=back

=head1 OS SUPPORT

QuickJS supports Linux, macOS, and Windows natively, so these work without
issue.

FreeBSD, OpenBSD, & Cygwin work after a few patches that we apply when
building this library. (Hopefully these will eventually merge into QuickJS.)

=head1 LIBATOMIC

QuickJS uses C11 atomics. Most platforms implement that functionality in
hardware, but others (e.g., arm32) don’t. To fill that void, we need to link
to libatomic.

This library’s build logic detects whether libatomic is necessary and will
only link to it if needed. If, for some reason, you need manual control over
that linking, set C in the environment to 1 or a
falsy value.

If you don’t know what any of that means, you can probably ignore it.

=head1 SEE ALSO

Other JavaScript modules on CPAN include:

=over

=item * L and L make the
L library available to Perl. They’re similar to
this library, but Duktape itself (as of this writing) lacks support for
several JavaScript constructs that QuickJS supports. (It’s also slower.)

=item * L and L expose Google’s
L library to Perl. Neither seems to support current
V8 versions.

=item * L is a pure-Perl (!) JavaScript engine.

=item * L and L expose Mozilla’s
L engine to Perl.

=back

=head1 LICENSE & COPYRIGHT

This library is copyright 2022 Gasper Software Consulting.

This library is licensed under the same terms as Perl itself.
See L.

QuickJS is copyright Fabrice Bellard and Charlie Gordon. It is released
under the L.

=cut

#----------------------------------------------------------------------

package JavaScript::QuickJS::JSObject;

package JavaScript::QuickJS::RegExp;

our @ISA;
BEGIN { @ISA = 'JavaScript::QuickJS::JSObject' };

package JavaScript::QuickJS::Function;

our @ISA;
BEGIN { @ISA = 'JavaScript::QuickJS::JSObject' };

1;