File Coverage

blib/lib/JSON/Util.pm

Criterion	Covered	Total	%
statement	52	52	100.0
branch	7	10	70.0
condition			n/a
subroutine	13	13	100.0
pod	5	5	100.0
total	77	80	96.2

package JSON::Util;

=head1 NAME

JSON::Util - easy and portable encode/decode of JSON

=head1 SYNOPSIS

    use JSON::Util;
    $data = JSON::Util->decode('{"bar": "foo"}');
    $data = JSON::Util->decode('some.json');
    JSON::Util->encode({ 'foo' => 'bar' }, 'someother.json');

    $data = JSON::Util->decode(['..', 'folder', some.json]);
    JSON::Util->encode([123,321], ['..', 'folder', someother.json]);

    print JSON::Util->encode([987,789]), "\n";
    print JSON::Util->encode({987 => 789}), "\n";

    my $json = JSON::Util->new(pretty => 0, convert_blessed => 1);
    print $json->encode([ $object, $object2 ]);

    # with file locking
    $data = JSON::Util->decode(['..', 'folder', some.json], { 'LOCK_SH' => 1 });
    $data = JSON::Util->decode(['..', 'folder', some.json], { 'LOCK_SH' => 1, LOCK_NB => 1 });
    JSON::Util->encode([123,321], ['..', 'folder', someother.json], { 'LOCK_EX' => 1 });
    JSON::Util->encode([123,321], ['..', 'folder', someother.json], { 'LOCK_EX' => 1, LOCK_NB => 1 });

=head1 DESCRIPTION

=cut

use warnings;
use strict;

our $VERSION = '0.06';

use 5.010;
use feature 'state';

use Scalar::Util 'blessed';
use IO::Any;
use Carp 'croak';
use JSON::MaybeXS;

=head1 METHODS

=head2 new()

Object constructor. Needed only when the L configuration
needs to be changed. Any key/value passed as parameter will be called on
C<new()>> as C<<$json->$key($value)>>.

=cut

sub new {
    my $class = shift;
    my %options = (
        'utf8'            => 1,
        'pretty'          => 1,
        'convert_blessed' => 1,
        @_
    );

    my $self  = bless \%options, __PACKAGE__;

    my $json = JSON::MaybeXS->new();
    while (my ($option, $value) = each %options) {
        $json->$option($value);
    }

    $self->{'json'} = $json;

    return $self;
}

=head2 default_json

Returns C<new()>> with:

        'utf8'            => 1,
        'pretty'          => 1,
        'convert_blessed' => 1,

=cut

sub default_json {
    my $class = shift;
    state $json = $class->new->{'json'};
    return $json;
}

=head2 json

Returns current L object.

=cut

sub json {
    return (blessed $_[0] ? $_[0]->{'json'} : $_[0]->default_json);
}

=head2 decode($what, [$opt])

Return ref with decoded C<$what>. See L for C<$where> and C<$opt>
description.

=cut

sub decode {
    my $self = shift;
    my $what = shift;
    my $opt  = shift;
    croak 'too many arguments'
        if @_;

    my $data = eval { $self->json->decode(IO::Any->slurp($what, $opt)) };
    my $error = $@; $error =~ s/\n$//;
    croak $error if $@;

    return $data;
}

=head2 encode($data, [$where], [$opt])

Returns encoded C<$data>. If C<$where> is passed then the result is
written there. See L for C<$where> and C<$opt> description.

=cut

sub encode {
    my $self = shift;
    my $data = shift;

    # with one argument just do json encode
    return $self->json->encode($data)
        if (@_ == 0);

    my $where = shift;
    my $opt   = shift;
    croak 'too many arguments'
        if @_;

    return IO::Any->spew($where, $self->json->encode($data), $opt);
}

1;


__END__