File Coverage

blib/lib/JSON/Schema/Shorthand.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	20	20	100.0
condition			n/a
subroutine	7	7	100.0
pod	1	1	100.0
total	72	72	100.0

package JSON::Schema::Shorthand;
our $AUTHORITY = 'cpan:YANICK';
# ABSTRACT: Alternative, condensed format for JSON Schemas
$JSON::Schema::Shorthand::VERSION = '0.0.2';
use strict;
use warnings;

use 5.20.0;

use experimental 'postderef';

use parent 'Exporter::Tiny';

our @EXPORT = ( 'js_shorthand' );

use Clone qw/ clone /;

sub js_shorthand {
    my $object = clone( shift );

    unless( ref $object ) {
        $object = { ( ( '#' eq substr $object, 0, 1 ) ? '$ref' : 'type' ) => $object };
    }

    if ( my $array = delete $object->{array} ) {
        $object->{type} = 'array';
        $object->{items} = ref $array eq 'ARRAY'
            ? [ map { js_shorthand($_) } @$array ]
            : js_shorthand( $array )
            ;
    }

    if( my $props = delete $object->{object} ) {
        $object->{type} = 'object';
        $object->{properties} = $props;
    }

    # foo => { bar => $schema }
    for my $keyword ( qw/ definitions properties / ) {
        next unless $object->{$keyword};
        $_ = js_shorthand($_) for values %{ $object->{$keyword} };
    }

    # foo => [ @schemas ]
    for my $keyword ( qw/ anyOf allOf oneOf / ) {
        next unless $object->{$keyword};
        $object->{$keyword} = [
            map { js_shorthand($_) } $object->{$keyword}->@*
        ];
    }

    # foo => $schemas
    for my $keyword ( qw/ not / ) {
        next unless $object->{$keyword};
        $object->{$keyword} = js_shorthand($object->{$keyword});
    }

    # required attribute
    if ( $object->{properties} ) {
        my @required = grep {
            delete $object->{properties}{$_}{required}
        } keys $object->{properties}->%*;

        $object->{required} = [
            eval { $object->{required}->@* },
            @required
        ] if @required;
    }

    return $object;
}

1;

__END__