File Coverage

blib/lib/JSON/Diffable.pm

Criterion	Covered	Total	%
statement	25	25	100.0
branch	4	4	100.0
condition			n/a
subroutine	7	7	100.0
pod	2	2	100.0
total	38	38	100.0

use strictures 1;

# lots of this stuff was sponsored by socialflow.com

package JSON::Diffable;

use JSON ();
use Exporter 'import';

our $VERSION = '0.000001'; # 0.0.1

$VERSION = eval $VERSION;

my $real = JSON->new->relaxed->allow_nonref->utf8;

our @EXPORT_OK = qw( encode_json decode_json );

sub encode_json {
    my $data = shift;
    return _encode($data, 0);
}

sub decode_json {
    my $str = shift;
    return $real->decode($str);
}

sub _indent {
    my $str = shift;
    $str =~ s{^}{  }gm;
    return $str;
}

sub _encode {
    my $data = shift;
    if (ref $data eq 'HASH') {
        return sprintf "{\n%s}",
            join '',
            map {
                my $key  = $real->encode($_);
                my $data = _encode($data->{$_});
                _indent("$key: $data") . ",\n";
            }
            sort keys %$data;
    }
    elsif (ref $data eq 'ARRAY') {
        return sprintf "[\n%s]",
            join '',
            map {
                _indent(_encode($_)) . ",\n";
            }
            @$data;
    }
    else {
        return $real->encode($data);
    }
}

1;

__END__