File Coverage

blib/lib/JIP/LockSocket.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	17	18	94.4
condition	5	6	83.3
subroutine	14	14	100.0
pod	0	4	0.0
total	82	88	93.1

package JIP::LockSocket;

use 5.006;
use strict;
use warnings;
use JIP::ClassField 0.05;
use Carp qw(croak);
use English qw(-no_match_vars);
use Socket qw(inet_aton pack_sockaddr_in PF_INET SOCK_STREAM);

our $VERSION = '0.021';

has [qw(port addr socket is_locked)] => (get => q{+}, set => q{-});

sub new {
    my ($class, %param) = @ARG;

    # Mandatory options
    croak q{Mandatory argument "port" is missing}
        unless exists $param{'port'};

    # Check "port"
    my $port = $param{'port'};
    croak q{Bad argument "port"}
        unless defined $port and $port =~ m{^\d+$}x;

    # Check "addr"
    my $addr = (exists $param{'addr'} and length $param{'addr'})
        ? $param{'addr'} : '127.0.0.1';

    # Class to object
    return bless({}, $class)
        ->_set_is_locked(0)
        ->_set_port($port)
        ->_set_addr($addr)
        ->_set_socket(undef);
}

# Lock or raise an exception
sub lock {
    my $self = shift;

    # Re-locking changes nothing
    return $self if $self->is_locked;

    my $socket = $self->_init_socket;

    bind($socket, pack_sockaddr_in($self->port, $self->_get_inet_addr))
        or croak(sprintf q{Can't lock port "%s": %s}, $self->port, $OS_ERROR);

    return $self->_set_socket($socket)->_set_is_locked(1);
}

# Or just return undef
sub try_lock {
    my $self = shift;

    # Re-locking changes nothing
    return $self if $self->is_locked;

    my $socket = $self->_init_socket;

    if (bind($socket, pack_sockaddr_in($self->port, $self->_get_inet_addr))) {
        return $self->_set_socket($socket)->_set_is_locked(1);
    }
    else {
        return;
    }
}

# You can manually unlock
sub unlock {
    my $self = shift;

    # Re-unlocking changes nothing
    return $self if not $self->is_locked;

    return $self->_set_socket(undef)->_set_is_locked(0);
}

# unlocking on scope exit
sub DESTROY {
    my $self = shift;
    return $self->unlock;
}

sub _get_inet_addr {
    my $self = shift;
    return inet_aton($self->addr);
}

sub _init_socket {
    socket(my $socket, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
        or croak(sprintf q{Can't init socket: %s}, $OS_ERROR);

    return $socket;
}

1;

__END__