File Coverage

blib/lib/Imager/Filter/Autocrop.pm

Criterion	Covered	Total	%
statement	83	91	91.2
branch	30	50	60.0
condition	23	38	60.5
subroutine	10	10	100.0
pod	0	1	0.0
total	146	190	76.8

package Imager::Filter::Autocrop;

use 5.006;
use strict;
use warnings;
use Imager;
use Imager::Color;

=head1 NAME

Imager::Filter::Autocrop - Automatic crop filter for Imager.

=head1 VERSION

Version 1.22

=head1 SYNOPSIS

    use Imager;
    use Imager::Filter::Autocrop;

    my $img = Imager->new();
    $img->read(file => 'image.jpg');
    $img->filter(type => 'autocrop') or die $img->errstr;

=head1 DESCRIPTION

This module extends C functionality with the autocrop filter, similar to ImageMagick and GraphicsMagick "trim". It does
have a few additional features as well, such as support for the border or detection-only mode. The distribution also includes
a command-line script autocrop.pl.

Note: If the image looks blank (whether genuinely or because of the 'fuzz' parameter), or if there is nothing to crop,
then the filter call will return false and the 'errstr' method will return appropriate message.

=head1 NAME OVERRIDE

You can change the name under which the filter is registered, by specifying it in 'use' directive. For example, to change the
name to 'trim' from the default 'autocrop':

    use Imager;
    use Imager::Filter::Autocrop 'trim';

    $img->filter(type => 'trim') or die $img->errstr;

=head1 PARAMETERS

=over 12

=item C

By default the color of the top left pixel is used for cropping. You can explicitly specify one though, by either
providing the '#RRGGBB' value or passing an object of C class or its subclass.

    # The following two calls are identical.
    $img->filter(type => 'autocrop', color => "#FFFFFF");
    $img->filter(type => 'autocrop', color => Imager::Color->new(255, 255, 255));

=item C

You can specify the deviation for the color value (for all RGB channels or the main channel if it is a greyscale image),
by using the 'fuzz' parameter. All image colors within the range would be treated as matching candidates for cropping.

    $img->filter(type => 'autocrop', fuzz => 20);

=item C

You can specify the border around the image for cropping. If the cropping area with the border is identical to the original
image height and width, then no actual cropping will be done.

    $img->filter(type => 'autocrop', border => 10);

=item C

Finally, you can just detect the cropping area by passing a hash reference as a 'detect' parameter. On success, your hash
will be set with left, right, top and bottom keys and appropriate values. Please note that if the 'border' parameter is used,
the detected area values will be adjusted appropriately.

    my %points = ();
    $img->filter(type => 'autocrop', detect => \%points);

=back

=cut

our $VERSION = '1.22';

sub autocrop {
    my (%params) = @_;
    my ($img, $fuzz, $border, $color, $detect) = @params{qw};
    $color||=$params{'colour'}; # Yes, we support British version too.
    # Check if colour is given, otherwise read the corner pixel.
    if ($color) {
        $color = Imager::Color->new($color) unless UNIVERSAL::isa($color, 'Imager::Color');
    } else {
        $color = $img->getpixel(x => 0, y => 0);
    }
    die "AUTOCROP_ERROR_COLOR: Color is not set correctly\n" unless defined $color;
    my ($r, $g, $b) = $color->rgba;
    my @range = ([ $r - $fuzz, $r + $fuzz ], [ $g - $fuzz, $g + $fuzz ], [ $b - $fuzz, $b + $fuzz ]);
    my $crop = _scan($img, \@range);
    my %original = (left => 0, right => $img->getwidth, top => 0, bottom => $img->getheight);
    my $bordered = 0;
    for (keys %original) {
        if ($original{$_}) {
            $crop->{$_}+=$border;
            if ($crop->{$_} >= $original{$_}) {
                $crop->{$_} = $original{$_};
                $bordered++;
            }
        } else {
            $crop->{$_}-=$border;
            if ($crop->{$_} <= $original{$_}) {
                $crop->{$_} = $original{$_};
                $bordered++;
            }
        }
    }
    die "AUTOCROP_ERROR_NOCROP: Nothing to crop\n" if ($bordered == 4);
    if ($detect and ref $detect eq 'HASH') {
        %{$detect} = %{$crop};
    } else {
        my $rv = $img->crop(%{$crop}) or die $img->errstr;
        $img->{IMG} = $rv->{IMG};
    }
}

sub _scan {
    my ($image, $range) = @_;
    my ($line, $top, $bottom, $left, $right, $lines) = (0, 0, 0, undef, undef, $image->getheight);
    my ($outline, $pos, $rpos, @colors, @scanned);
    my $channels = $image->getchannels < 3 ? 0 : 2;
    for ($line = $lines - 1; $line >= 0; $line--) {
        ($outline, $pos, $rpos) = _outline($image, $line, $range, $channels);
        last if $outline;
    }
    die "AUTOCROP_ERROR_BLANK: Image looks blank\n" unless $outline;
    $bottom = $line;
    ($left, $right) = ($pos, $rpos) if $outline;
    for ($line = 0; $line < $bottom; $line++) {
        # NB - don't use left/right boundaries here
        ($outline, $pos, $rpos) = _outline($image, $line, $range, $channels);
        last if $outline;
    }
    $top = $line;
    if ($outline) {
        $left = $pos if (!defined $left or $pos < $left);
        $right = $rpos if (!defined $right or $rpos > $right);
    }
    for ($line = $top + 1; $line < $bottom; $line++) {
        ($outline, $pos, $rpos) = _outline($image, $line, $range, $channels, $left, $right);
        if ($outline) {
            $left = $pos if (!defined $left or $pos < $left);
            $right = $rpos if (!defined $right or $rpos > $right);
        }
    }
    $right++ if defined $right;
    $bottom++ if defined $bottom;
    return { top => $top, bottom => $bottom, left => $left, right => $right };
}

sub _outline {
    my ($image, $line, $range, $channels, $left, $right) = @_;
    my @colors = unpack "C*", $image->getscanline(y => $line);
    my ($outline, $routline, $pos, $rpos) = (0, 0, 0, @colors/4 - 1);
    my @color;
    while (@colors) {
        @color = splice @colors, 0, 4;
        $outline = _out_of_range(\@color, $range, $channels);
        last if ($outline or (defined $left and $pos >= $left));
        $pos++;
    }
    while (@colors) {
        @color = splice @colors, -4, 4;
        $routline = _out_of_range(\@color, $range, $channels);
        last if ($routline or (defined $right and $rpos <= $right));
        $rpos--;
    }
    return ($outline||$routline, $pos, $rpos);
}

sub _out_of_range {
    my ($scanned, $range, $channels) = @_;
    for (0 .. $channels) {
        if ($scanned->[$_] < $range->[$_]->[0] or $scanned->[$_] > $range->[$_]->[1]) {
            return 1;
        }
    }
    return 0;
}

sub import {
    my ($self, $type) = @_;
    Imager->register_filter(
    type => $type||'autocrop',
    callsub => \&autocrop,
    callseq => [ 'image' ],
    defaults => {
        fuzz    => 0,
        border  => 0,
    });
}

=head1 SEE ALSO

L

=head1 AUTHOR

Alexander Yezhov, C<<  >>
Domain Knowledge Ltd.
L

=head1 BUGS

Please report any bugs or feature requests to C, or through
the web interface at L.  I will be notified, and then you'll
automatically be notified of progress on your bug as I make changes.



=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc Imager::Filter::Autocrop


You can also look for information at:

=over 4

=item * RT: CPAN's request tracker (report bugs here)

L

=item * AnnoCPAN: Annotated CPAN documentation

L

=item * CPAN Ratings

L

=item * Search CPAN

L

=back


=head1 LICENSE AND COPYRIGHT

Copyright 2016 Alexander Yezhov.

This program is free software; you can redistribute it and/or modify it
under the terms of the Artistic License (2.0). You may obtain a
copy of the full license at:

L

Any use, modification, and distribution of the Standard or Modified
Versions is governed by this Artistic License. By using, modifying or
distributing the Package, you accept this license. Do not use, modify,
or distribute the Package, if you do not accept this license.

If your Modified Version has been derived from a Modified Version made
by someone other than you, you are nevertheless required to ensure that
your Modified Version complies with the requirements of this license.

This license does not grant you the right to use any trademark, service
mark, tradename, or logo of the Copyright Holder.

This license includes the non-exclusive, worldwide, free-of-charge
patent license to make, have made, use, offer to sell, sell, import and
otherwise transfer the Package with respect to any patent claims
licensable by the Copyright Holder that are necessarily infringed by the
Package. If you institute patent litigation (including a cross-claim or
counterclaim) against any party alleging that the Package constitutes
direct or contributory patent infringement, then this Artistic License
to you shall terminate on the date that such litigation is filed.

Disclaimer of Warranty: THE PACKAGE IS PROVIDED BY THE COPYRIGHT HOLDER
AND CONTRIBUTORS "AS IS' AND WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
THE IMPLIED WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
PURPOSE, OR NON-INFRINGEMENT ARE DISCLAIMED TO THE EXTENT PERMITTED BY
YOUR LOCAL LAW. UNLESS REQUIRED BY LAW, NO COPYRIGHT HOLDER OR
CONTRIBUTOR WILL BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, OR
CONSEQUENTIAL DAMAGES ARISING IN ANY WAY OUT OF THE USE OF THE PACKAGE,
EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.


=cut

1;