File Coverage

blib/lib/IPC/Run/Fused/POSIX.pm

Criterion	Covered	Total	%
statement	25	31	80.6
branch	8	16	50.0
condition	3	6	50.0
subroutine	5	6	83.3
pod	1	1	100.0
total	42	60	70.0

use strict;
use warnings;

package IPC::Run::Fused::POSIX;
BEGIN {
  $IPC::Run::Fused::POSIX::AUTHORITY = 'cpan:KENTNL';
}
{
  $IPC::Run::Fused::POSIX::VERSION = '0.04000100';
}

use IO::Handle;

# ABSTRACT: Implementation of IPC::Run::Fused for POSIX-ish systems.


sub _fail { goto \&IPC::Run::Fused::_fail }

sub run_fused {
  my ( $read_handle, @params ) = @_;

  my ( $reader, $writer );

  pipe( $reader, $writer ) or _fail('Creating Pipe');

  if ( my $pid = fork() ) {
    $_[0] = $reader;
    return $pid;
  }

  open *STDOUT, '>>&=', $writer->fileno or _fail('Assigning to STDOUT');
  open *STDERR, '>>&=', $writer->fileno or _fail('Assigning to STDERR');

  if ( ref $params[0] and ref $params[0] eq 'CODE' ) {
    $params[0]->();
    exit;
  }
  if ( ref $params[0] and ref $params[0] eq 'SCALAR' ) {
    my $command = ${ $params[0] };
    exec $command or _fail('<> failed');
    exit;
  }

  my $program = $params[0];
  exec {$program} @params or _fail('<> failed');
  exit;
}

1;

__END__