File Coverage

blib/lib/IO/EditPrompt.pm

Criterion	Covered	Total	%
statement	52	60	86.6
branch	14	24	58.3
condition	11	13	84.6
subroutine	11	12	91.6
pod	2	2	100.0
total	90	111	81.0

package IO::EditPrompt;

use warnings;
use strict;

use File::Temp ();
use IO::Prompter ();

our $VERSION = '0.02';

sub new {
    my ($class, $opts) = (@_);

    $opts ||= {};
    die "parameter is not a hashref.\n" unless ref $opts eq ref {};
    die "'$opts->{tmpdir}' is not a directory.\n" if defined $opts->{tmpdir} and !-d $opts->{tmpdir};

    my $self = bless {
        dir => $opts->{tmpdir},
        editor => $opts->{editor},
        editor_args => [],
    }, $class;
    $self->_normalize_editor( $opts->{default_editor} );
    return $self;
}

sub prompt {
    my ($self, $prompt, $deftext) = @_;

    my $output = '';
    my $fmt_prompt = _format_prompt( $prompt );

    do {
        my ($tmp, $filename) = $self->_create_tmp_file( $fmt_prompt, $deftext );
        $self->_run_editor( $filename );
        $output = $self->_get_output( $filename, $fmt_prompt );
    } while( (0 == length $output) && IO::Prompter::prompt( 'Content is empty, retry?', '-y' ) );

    return $output;
}

sub _normalize_editor {
    my ($self, $def_editor) = @_;
    $self->{editor} ||= $ENV{EDITOR} || $def_editor || 'vim';

    # Turn off saving state on vim
    $self->{editor_args} = [ '-i', 'NONE' ] if $self->{editor} =~ /\bvim$/;
    return;
}

sub _format_prompt {
    my ($prompt) = @_;
    return '' unless defined $prompt;
    return join( q{}, map { "# $_\n" } split /\n/, $prompt );
}

sub _create_tmp_file {
    my ($self, @texts) = @_;

    my $tmp = File::Temp->new( UNLINK => 1, EXLOCK => 1, ($self->{dir} ? (DIR => $self->{dir}) : ()) );
    my $filename = $tmp->filename;
    print {$tmp} grep { defined $_ } @texts;
    close( $tmp ) or die "Unable to write '$filename': $!\n";

    return ($tmp, $filename);
}

sub _read_file {
    my ($self, $filename) = @_;
    open my $fh, '<', $filename or die "Unable to re-read '$filename': $!\n";
    local $/;
    return scalar <$fh>;
}

sub _get_output {
    my ($self, $filename, $prompt) = @_;
    return '' if  -s $filename eq length $prompt;
    my $output = $self->_read_file( $filename );
    $output =~ s/^#[^\n]*(?:\n|\Z)//smg;
    return $output;
}

sub _run_editor {
    my ($self, $file) = @_;
    my $err = system $self->{editor}, @{$self->{editor_args}}, $file;
    return unless $err;
    if ($? == -1) {
        die "failed to execute '$self->{editor}': $!\n";
    }
    elsif ($? & 127) {
        die sprintf "'$self->{editor}' died with signal %d, %s coredump\n",
            ($? & 127),  ($? & 128) ? 'with' : 'without';
    }
    else {
        die sprintf "'$self->{editor}' exited with value %d\n", $? >> 8;
    }
}

1;
__END__