File Coverage

blib/lib/IO/Uncompress/UnZstd.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	8	10	80.0
condition			n/a
subroutine	17	17	100.0
pod	2	9	22.2
total	86	95	90.5

package IO::Uncompress::UnZstd ;

use strict ;
use warnings;
use bytes;

use IO::Compress::Base::Common  2.206 qw(:Status createSelfTiedObject);

use IO::Uncompress::Base  2.206 ;
use IO::Uncompress::Adapter::UnZstd  2.206 ;


require Exporter ;
our ($VERSION, @ISA, @EXPORT_OK, %EXPORT_TAGS, $UnZstdError);

$VERSION = '2.206';
$UnZstdError = '';

@ISA    = qw( IO::Uncompress::Base Exporter );
@EXPORT_OK = qw( $UnZstdError unzstd ) ;
#%EXPORT_TAGS = %IO::Uncompress::Base::EXPORT_TAGS ;
push @{ $EXPORT_TAGS{all} }, @EXPORT_OK ;
#Exporter::export_ok_tags('all');

use constant SIGNATURE => 'ZV';

sub new
{
    my $class = shift ;
    my $obj = createSelfTiedObject($class, \$UnZstdError);

    $obj->_create(undef, 0, @_);
}

sub unzstd
{
    my $obj = createSelfTiedObject(undef, \$UnZstdError);
    return $obj->_inf(@_);
}

sub getExtraParams
{
    return ();
}

sub ckParams
{
    my $self = shift ;
    my $got = shift ;

    return 1;
}


sub postCheckParams
{
    my $self = shift ;
    my $got = shift ;

    # return  $self->saveErrorString(undef, "MultiStream not supported by Zstd", STATUS_ERROR)
    #     if $got->getValue('multistream') ;

    # Compress::Stream::Zstd is only multi-stream
    $got->setValue('multistream' => 1);
    return 1;
}

sub mkUncomp
{
    my $self = shift ;
    my $got = shift ;

     my $magic = $self->ckMagic()
        or return 0;

    *$self->{Info} = $self->readHeader($magic)
        or return undef ;

    my ($obj, $errstr, $errno) = IO::Uncompress::Adapter::UnZstd::mkUncompObject();

    return $self->saveErrorString(undef, $errstr, $errno)
        if ! defined $obj;

    *$self->{Uncomp} = $obj;

    return 1;
}


sub ckMagic
{
    my $self = shift;

    use constant ZSTD_MAGICNUMBER  =>  0xFD2FB528  ; # >= v0.8.0

    my $magic ;
    $self->smartReadExact(\$magic, 4);

    *$self->{HeaderPending} = $magic ;

    return $self->HeaderError("Header size is " .
                                        4 . " bytes")
        if length $magic != 4;

    return $self->HeaderError("Bad Magic.")
        if  unpack("V*", $magic) != ZSTD_MAGICNUMBER;


    *$self->{Type} = 'zstd';
    return $magic;
}

sub readHeader
{
    my $self = shift;
    my $magic = shift ;

    $self->pushBack($magic);
    *$self->{HeaderPending} = $magic;

    return {
        'Type'              => 'zstd',
        'FingerprintLength' => 4,
        'HeaderLength'      => 4,
        'TrailerLength'     => 0,
        'Header'            => $magic
        };
}

sub chkTrailer
{
    return STATUS_OK;
}



1 ;

__END__