File Coverage

blib/lib/INI_File.pm

Criterion	Covered	Total	%
statement	71	79	89.8
branch	16	32	50.0
condition			n/a
subroutine	21	25	84.0
pod	0	6	0.0
total	108	142	76.0

package INI_File;
BEGIN {
  $INI_File::AUTHORITY = 'cpan:GETTY';
}
# ABSTRACT: Tie a hash or an array to an INI file
$INI_File::VERSION = '0.001';
use Moo;
use Config::INI::Reader;
use Config::INI::Writer;
use Path::Class;
use Data::Dumper;

has filename => (
  is => 'ro',
  required => 1,
);

has abs_filename => (
  is => 'ro',
  lazy => 1,
  default => sub { file(shift->filename)->absolute },
);

sub BUILD {
  my ( $self ) = @_;
  $self->abs_filename;
}

sub data {
  my ( $self ) = @_;
  if (-f $self->abs_filename) {
    return $self->load_file;
  } else {
    return {};
  }
}

sub add_data {
  my ( $self, $key, $value ) = @_;
  print "add_data:".$key.":".Dumper($value)."\n" if $ENV{INI_FILE_TRACE};
  my $data = $self->data;
  $data->{$key} = $value;
  $self->save_file($data);
}

sub remove_data {
  my ( $self, $key ) = @_;
  print "remove_data:".$key."\n" if $ENV{INI_FILE_TRACE};
  my $data = $self->data;
  delete $data->{$key};
  $self->save_file($data);
}

sub load_file {
  my ( $self ) = @_;
  print __PACKAGE__.":load_file\n" if $ENV{INI_FILE_TRACE};
  return Config::INI::Reader->read_file($self->abs_filename);
}

sub save_file {
  my ( $self, $data ) = @_;
  print __PACKAGE__.":save_file:".Dumper($data) if $ENV{INI_FILE_TRACE};
  return Config::INI::Writer->write_file($data,$self->abs_filename);
}

sub TIEHASH {
  my ( $class, $filename, @args ) = @_;
  print __PACKAGE__.":TIEHASH:".$filename.(scalar @args ? ":".Dumper(@args) : "\n") if $ENV{INI_FILE_TRACE};
  $class->new(
    filename => $filename,
    @args,
  );
}

sub FETCH {
  my ( $self, $key ) = @_;
  print __PACKAGE__.":FETCH:".$key."\n" if $ENV{INI_FILE_TRACE};
  return $self->data->{$key};
}

sub STORE {
  my ( $self, $key, $value ) = @_;
  print __PACKAGE__.":STORE:".$key.":".Dumper($value) if $ENV{INI_FILE_TRACE};
  $self->add_data($key,$value);
}

sub DELETE {
  my ( $self, $key ) = @_;
  print __PACKAGE__.":DELETE:".$key."\n" if $ENV{INI_FILE_TRACE};
  $self->remove_data($key)
}

sub EXISTS {
  my ( $self, $key ) = @_;
  print __PACKAGE__.":EXISTS:".$key."\n" if $ENV{INI_FILE_TRACE};
  return exists $self->data->{$key};
}

sub SCALAR {
  my ( $self ) = @_;
  print __PACKAGE__.":SCALAR\n" if $ENV{INI_FILE_TRACE};
  return scalar %{$self->data};
}

sub CLEAR {
  my ( $self ) = @_;
  print __PACKAGE__.":CLEAR\n" if $ENV{INI_FILE_TRACE};
  $self->save_file({});
}

sub EXTEND {}
sub STORESIZE {}

sub FIRSTKEY {
  my ( $self ) = @_;
  my ( $first ) = sort { $a cmp $b } keys %{$self->data};
  return defined $first ? ($first) : ();
}

sub NEXTKEY {
  my ( $self, $last ) = @_;
  my @sorted_keys = sort { $a cmp $b } keys %{$self->data};
  while (@sorted_keys) {
    my $key = shift @sorted_keys;
    if ($key eq $last) {
      if (@sorted_keys) {
        return (shift @sorted_keys);
      } else {
        return;
      }
    }
  }
}

sub UNTIE {}
sub DESTROY {}

1;

__END__