File Coverage

blib/lib/IBM/StorageSystem/Node.pm

Criterion	Covered	Total	%
statement	33	76	43.4
branch	0	6	0.0
condition	0	4	0.0
subroutine	11	15	73.3
pod	0	1	0.0
total	44	102	43.1

package IBM::StorageSystem::Node;

use strict;
use warnings;

use IBM::StorageSystem::Statistic::Node::Memory;
use IBM::StorageSystem::Statistic::Node::CPU;
use IBM::StorageSystem::Statistic::Node::DiskRead;
use IBM::StorageSystem::Statistic::Node::DiskWrite;
use Carp qw(croak);
use Scalar::Util qw(weaken);

our $VERSION = '0.02';
our @ATTR = qw(	CTDB_status	connection_status	CTDB_IP_address		daemon_IP_address
		daemon_version	description		GPFS_status		hostname
		IP		is_cache		is_manager		is_quorum
		last_updated	monitoring_enabled	OS_family		OS_name
		product_version	recovery_master 	role			serial_number
		username 	version
	     );

foreach my $attr ( @ATTR ) {
	{
		no strict 'refs';
		*{ __PACKAGE__ .'::'. $attr } =	sub {
			my( $self, $val ) = @_;
			$val =~ s/\#/no/ if $val;
			$self->{$attr} = $val if $val;
			return $self->{$attr}
		}
	}
}

our $STATS = {
		memory => {
			cmd	=> '-g memory_stats',
			class	=> 'IBM::StorageSystem::Statistic::Node::Memory'
			},
		cpu => {
			cmd	=> '-g cpu_stats',
			class	=> 'IBM::StorageSystem::Statistic::Node::CPU'
			}
};

foreach my $stat ( keys %{ $STATS } ) {
	{
		no strict 'refs';
		*{ __PACKAGE__ .'::'. $stat } = sub {
			my( $self, $t ) = @_;
			$t ||= 'minute';
			my $stats = $self->{__ibm}->__lsperfdata(
						cmd   => "$STATS->{$stat}->{cmd} -t $t -n $self->{hostname}",
						class => $STATS->{$stat}->{class}
							);
			return $stats
		}
	}
}

foreach my $m ( qw(reads writes) ) {
	{
	no strict 'refs';
	*{ __PACKAGE__ .'::disk_'. $m } = sub {
		my( $self, $t ) = @_;
		$t ||= 'minute';
		my $stats = IBM::StorageSystem::StatisticsSet->new;
		my( $headers, @stats ) = split( /\n/,
			$self->{__ibm}->__cmd( "lsperfdata -g disk_$m -t $t -n $self->{hostname}" ) );
		# disk_reads and disk_writes perfdata stats use non-parsable CSV for the column headers
		# This neccesitates the ugliness below
		pop @stats;
		my @cols = split /\[#\]/, $headers;
		my @f = ( split /,/, shift @cols )[0,1,3];

		for ( @cols ) { push @f, ( split /,/ )[2] }

		@cols = map {	s/^ *//;
				s/ *$//;
				s/ /_/g;
				s/-/_/g;
				lc($_)
			} @f;

		foreach my $stat ( @stats ) {
			my @values = split /,/, $stat;
			( my $m = 'IBM::StorageSystem::Statistic::Node::Disk' . ucfirst $m ) =~ s/s$//;
			my $s = $m->new;
			my $c = 0;

			foreach my $col ( @cols ) {
				$s->$col( $values[$c++] );
			}

			$stats->__push( $s )
		}

		return $stats
	}
	}
}

sub new {
        my( $class, $ibm, %args ) = @_;
        my $self = bless {}, $class;
	weaken( $self->{__ibm} = $ibm );

        defined $args{Hostname} or croak 'Constructor failed: mandatory Hostname argument not supplied';

	# Modify the passed arg attribute names for nicer formatting - lower cased except for acronyms
	foreach my $attr ( keys %args ) {
		my $mattr = lc $attr;

		foreach my $s ( qw(ctdb gpfs ip os) ) {
			my $u = uc $s;
			$mattr =~ s/(^|_)($s)/$1$u/g
		}

		$self->{$mattr} = $args{$attr}
	}

	return $self;
}

1;

__END__