File Coverage

blib/lib/Hash/Util/Merge.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	2	2	100.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	51	51	100.0

package Hash::Util::Merge;

use v5.14;
use warnings;

use Exporter 5.57 ();
use Sub::Util 1.40 qw( set_prototype );

our $VERSION = 'v0.2.0';

# ABSTRACT: utility functions for merging hashes


our @EXPORT_OK = qw/ mergemap /;

sub import {

    # This borrows a technique from List::Util that exports symbols $a
    # and $b to the callers namespace, so that function arguments can
    # simply use $a and $b, akin to how function arguments for sort
    # works.

    my $pkg = caller;
    no strict 'refs'; ## no critic (ProhibitNoStrict)
    ${"${pkg}::a"} = ${"${pkg}::a"};
    ${"${pkg}::b"} = ${"${pkg}::b"};
    goto &Exporter::import;
}


sub mergemap {

    my $pkg = caller;
    no strict 'refs'; ## no critic (ProhibitNoStrict)
    my $glob_a = \ *{"${pkg}::a"};
    my $glob_b = \ *{"${pkg}::b"};

    my ($f, $x, $y) = @_;

    my %r;

    for my $k (keys %$x, keys %$y) {
        next if exists $r{$k};
        local *$glob_a = \ $x->{$k};
        local *$glob_b = \ $y->{$k};
        $r{$k} = $f->();
    }

    return \%r;
}

BEGIN {
    set_prototype '&$$' => \&mergemap;
}


1;

__END__