File Coverage

blib/lib/Hash/DefaultValue.pm

Criterion	Covered	Total	%
statement	44	45	97.7
branch	9	10	90.0
condition			n/a
subroutine	13	13	100.0
pod			n/a
total	66	68	97.0

package Hash::DefaultValue;

use 5.006;
use strict;
use warnings;
use utf8;

use Tie::Hash qw();
use Carp qw(croak);

use constant {
	IDX_HASH   => 0,
	IDX_CODE   => 1,
	NEXT_IDX   => 2,
};
use constant _default => undef;

BEGIN {
	no warnings 'once';
	$Hash::DefaultValue::AUTHORITY = 'cpan:TOBYINK';
	$Hash::DefaultValue::VERSION   = '0.007';
	@Hash::DefaultValue::ISA       = qw(Tie::ExtraHash);
}

sub TIEHASH
{
	my $class    = shift;
	my $coderef  = @_ ? shift : $class->_default;

	unless (ref $coderef)
	{
		my $value = $coderef;
		$coderef = sub { $value };
	}

	unless (ref $coderef eq 'CODE')
	{
		croak "must provide a coderef or non-reference scalar value for $class";
	}

	$class->SUPER::TIEHASH($coderef)
}

sub FETCH
{
	my ($this, $key)  = @_;
	$key = '' unless defined $key;

	unless (exists $this->[IDX_HASH]{$key})
	{
		local $_ = $key;
		return scalar $this->[IDX_CODE]($this->[IDX_HASH], $key);
	}

	$this->[IDX_HASH]{$key}
}

__PACKAGE__
__END__