File Coverage

lib/Haineko/SMTPD/Milter/Example.pm

Criterion	Covered	Total	%
statement	61	63	96.8
branch	21	28	75.0
condition	21	29	72.4
subroutine	9	9	100.0
pod	6	6	100.0
total	118	135	87.4

package Haineko::SMTPD::Milter::Example;
use strict;
use warnings;
use parent 'Haineko::SMTPD::Milter';

sub conn {
    my $class = shift;
    my $nekor = shift || return 1;  # (Haineko::SMTPD::Response) Object
    my $argvs = [ @_ ];

    my $remotehost = $argvs->[0] // q();
    my $remoteaddr = $argvs->[1] // q();

    if( $remotehost eq 'localhost.localdomain' ) {
        # Reject ``localhost.localdomain''
        $nekor->error(1);
        $nekor->message( [ 'Error message here' ] );

    } elsif( $remoteaddr eq '255.255.255.255' ) {
        # Reject ``255.255.255.255''
        $nekor->error(1);
        $nekor->message( [ 'Broadcast address' ] );

        # Or Check REMOTE_ADDR with DNSBL...
    }

    return $nekor->error ? 0 : 1;
}

sub ehlo {
    my $class = shift;
    my $nekor = shift || return 1;  # (Haineko::SMTPD::Response) Object
    my $argvs = shift // q();       # (String) Hostname or IP address

    if( $argvs =~ m/[.]local\z/ ) {
        # Reject ``EHLO *.local''
        $nekor->code(521);
        $nekor->error(1);
        $nekor->message( [ 'Invalid domain ".local"' ] );
    }

    return $nekor->error ? 0 : 1;
}

sub mail {
    my $class = shift;
    my $nekor = shift || return 1;  # (Haineko::SMTPD::Response) Object
    my $argvs = shift // q();       # (String) Envelope sender address

    my $invalidtld = [ 'local', 'test', 'invalid' ];
    my $spamsender = [ '[e-mail]', '[e-mail]' ];

    if( grep { $argvs =~ m/[.]$_\z/ } @$invalidtld ) {
        # Reject by domain part of envelope sender address
        $nekor->error(1);
        $nekor->message( [ 'sender domain does not exist' ] );

    } elsif( grep { $argvs eq $_ } @$spamsender ) {
        # Not allowed address
        $nekor->error(1);
        $nekor->message( [ 'spammer is not allowed to send'] );
    }

    return $nekor->error ? 0 : 1;
}

sub rcpt {
    my $class = shift;
    my $nekor = shift || return 1;  # (Haineko::SMTPD::Response) Object
    my $argvs = shift // [];        # (String) Envelope recipient addresses
    my $bccto = '[e-mail]';

    push @$argvs, $bccto unless grep { $bccto eq $_ } @$argvs;
    return $nekor->error ? 0 : 1;
}

sub head {
    my $class = shift;
    my $nekor = shift || return 1;  # (Haineko::SMTPD::Response) Object
    my $argvs = shift // {};        # (Ref->Hash) Email header

    if( exists $argvs->{'subject'} && $argvs->{'subject'} =~ /spam/i ) {
        # Reject if the subject contains text ``spam''
        $nekor->error(1);
        $nekor->dsn('5.7.1');
        $nekor->message( [ 'DO NOT SEND spam' ] );
    }

    return $nekor->error ? 0 : 1;
}

sub body {
    my $class = shift;
    my $nekor = shift || return 1;  # (Haineko::SMTPD::Response) Object
    my $argvs = shift // return 1;  # (Ref->Scalar) Email body

    if( $$argvs =~ m{https?://} ) {
        # Do not include any URL in email body
        $nekor->error(1);
        $nekor->message( [ 'Not allowed to send an email including URL' ] );
    }

    return $nekor->error ? 0 : 1;
}

1;
__END__