File Coverage

blib/lib/HTTP/OAI/Harvester.pm

Criterion	Covered	Total	%
statement	40	44	90.9
branch	9	14	64.2
condition	9	15	60.0
subroutine	13	13	100.0
pod	6	8	75.0
total	77	94	81.9

package HTTP::OAI::Harvester;

use base HTTP::OAI::UserAgent;

use strict;

our $VERSION = '4.13';

sub new {
	my ($class,%args) = @_;
	my %ARGS = %args;
	delete @ARGS{qw(baseURL resume repository handlers onRecord)};
	my $self = $class->SUPER::new(%ARGS);

	$self->{doc} = XML::LibXML::Document->new( '1.0', 'UTF-8' );

	$self->{'resume'} = exists($args{resume}) ? $args{resume} : 1;

	if ($ENV{HTTP_OAI_AGENT}) {
		$self->agent($ENV{HTTP_OAI_AGENT});
	}
	else {
		$self->agent('OAI-PERL/'.$HTTP::OAI::VERSION);
	}

	# Record the base URL this harvester instance is associated with
	$self->{repository} =
		$args{repository} ||
		HTTP::OAI::Identify->new(baseURL=>$args{baseURL});
	Carp::croak "Requires repository or baseURL" unless $self->repository and $self->repository->baseURL;

	# Canonicalise
	$self->baseURL($self->baseURL);

	return $self;
}

sub resume { shift->_elem('resume',@_) }
sub repository { shift->_elem('repository',@_) }

sub baseURL {
	my $self = shift;
	return @_ ?
		$self->repository->baseURL(URI->new(shift)->canonical) :
		$self->repository->baseURL();
}
sub version { shift->repository->protocolVersion(@_); }

sub ListIdentifiers { shift->_list( @_, verb => "ListIdentifiers" ); }
sub ListRecords { shift->_list( @_, verb => "ListRecords" ); }
sub ListSets { shift->_list( @_, verb => "ListSets" ); }
sub _list
{
	my $self = shift;

	local $self->{recursion};
	my $r = $self->_oai( @_ );

	# resume the partial list?
	# note: noRecordsMatch is a "success" but won't have a resumptionToken
	RESUME: while($self->resume && $r->is_success && !$r->error && defined(my $token = $r->resumptionToken))
	{
		last RESUME if !$token->resumptionToken;
		local $self->{recursion};
		$r = $self->_oai(
			onRecord => $r->{onRecord},
			handlers => $r->handlers,
			verb => $r->verb,
			resumptionToken => $token->resumptionToken,
		);
	}

	$self->version( $r->version ) if $r->is_success;

	return $r;
}

# build the methods for each OAI verb
foreach my $verb (qw( GetRecord Identify ListMetadataFormats ))
{
	no strict "refs";
	*$verb = sub {
		my $self = shift;
		local $self->{recursion};

		my $r = $self->_oai( @_, verb => $verb );

		$self->version( $r->version ) if $r->is_success;

		return $r;
	};
}

1;

__END__