File Coverage

blib/lib/HTTP/OAI/Header.pm

Criterion	Covered	Total	%
statement	33	39	84.6
branch	14	20	70.0
condition	1	6	16.6
subroutine	8	10	80.0
pod	7	8	87.5
total	63	83	75.9

package HTTP::OAI::Header;

@ISA = qw( HTTP::OAI::MemberMixin HTTP::OAI::SAX::Base );

use strict;

our $VERSION = '4.11';

use POSIX qw/strftime/;

sub identifier { shift->_elem('identifier',@_) }
sub datestamp {
	my $self = shift;
	return $self->_elem('datestamp') unless @_;
	my $ds = shift or return $self->_elem('datestamp',undef);
	if( $ds =~ /^(\d{4})(\d{2})(\d{2})$/ ) {
		$ds = "$1-$2-$3";
	} elsif( $ds =~ /^(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})$/ ) {
		$ds = "$1-$2-$3T$4:$5:$6Z";
	}
	return $self->_elem('datestamp',$ds);
}
sub status { shift->_elem('status',@_) }
sub setSpec { shift->_multi('setSpec',@_) }

sub now { return strftime("%Y-%m-%dT%H:%M:%SZ",gmtime()) }

sub is_deleted { my $s = shift->status(); return defined($s) && $s eq 'deleted'; }

sub generate
{
	my ($self, $driver) = @_;

	if( defined($self->status) ) {
		$driver->start_element( 'header', status => $self->status );
	} else {
		$driver->start_element( 'header' );
	}
	$driver->data_element( 'identifier', $self->identifier );
	$driver->data_element( 'datestamp', ($self->datestamp || $self->now) );
	for($self->setSpec)
	{
		$driver->data_element( 'setSpec', $_ );
	}
	$driver->end_element( 'header' );
}

sub end_element {
	my ($self,$hash) = @_;
	my $elem = lc($hash->{LocalName});
	my $text = $hash->{Text};
	if( defined $text )
	{
		$text =~ s/^\s+//;
		$text =~ s/\s+$//;
	}
	if( $elem eq 'identifier' ) {
		$self->identifier($text);
	} elsif( $elem eq 'datestamp' ) {
		$self->datestamp($text);
	} elsif( $elem eq 'setspec' ) {
		$self->setSpec($text);
	} elsif( $elem eq 'header' ) {
		$self->status($hash->{Attributes}->{'{}status'}->{Value});
	}
}

1;

__END__