File Coverage

blib/lib/HTTP/MobileAgent/Flash.pm

Criterion	Covered	Total	%
statement	58	58	100.0
branch	15	16	93.7
condition	1	2	50.0
subroutine	16	16	100.0
pod	2	2	100.0
total	92	94	97.8

package HTTP::MobileAgent::Flash;
use strict;
use warnings;
use vars qw($VERSION);
$VERSION = '0.20';
use 5.008001;

use HTTP::MobileAgent;
use HTTP::MobileAgent::Flash::DoCoMoFlashMap;
use HTTP::MobileAgent::Flash::EZWebFlashMap;
use HTTP::MobileAgent::Flash::SoftBankFlashMap;

use Carp;

use base qw(Class::Accessor);
__PACKAGE__->mk_ro_accessors(qw(max_file_size version width height));

sub import {
    my $class = shift;
    no strict 'refs';
    *{"HTTP\::MobileAgent\::flash"}       = \&_flash;
    *{"HTTP\::MobileAgent\::is_flash"}    = \&_is_flash;
}

sub _flash {
    my $self = shift;
    unless ($self->{flash}) {
        $self->{flash} = HTTP::MobileAgent::Flash->new($self);
    }
    return $self->{flash};
}

sub _is_flash {
    my $self = shift;
    return ($self->flash->version > 0)? 1 : 0;
}

sub new {
    my ($class, $agent) = @_;

    my $map;
    if ($agent->is_docomo) {
        $map = $HTTP::MobileAgent::Flash::DoCoMoFlashMap::FLASH_MAP->{uc($agent->model)};
    }
    elsif ($agent->is_ezweb) {
        $map = $HTTP::MobileAgent::Flash::EZWebFlashMap::FLASH_MAP->{uc($agent->model)};
    }
    elsif ($agent->is_softbank) {
        $map = $HTTP::MobileAgent::Flash::SoftBankFlashMap::FLASH_MAP->{uc($agent->model)};
    }

    if ($map) {
        return bless $map, $class;
    }
    else {
        return bless {
            max_file_size => -1,
            version       => -1,
            width         => -1,
            height        => -1,
        }, $class;
    }
}

sub is_supported {
    my $self = shift;
    my $version = shift || "";

    croak "You must set version before call is_supported()" if ($version eq "");

    $version =~ s/Lite//ig;
    return ($version <= $self->version)? 1 : 0;
}

1;
__END__