File Coverage

blib/lib/HTML/Template/Compiled/Filter/Whitespace.pm

Criterion	Covered	Total	%
statement	13	13	100.0
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod	2	2	100.0
total	20	20	100.0

package HTML::Template::Compiled::Filter::Whitespace; ## no critic (TidyCode)

use strict;
use warnings;

our $VERSION = '0.09';

use parent qw( Exporter::Tiny );

our @EXPORT_OK = qw(
    get_whitespace_filter
    whitespace_filter
);
our $DEBUG;

my $inplace_whitespace_filter = sub {
    my $scalarref = shift;

    return if $DEBUG;
    ${$scalarref} =~ tr{\0}{ };
    my @unclean;
    while (
        ${$scalarref} =~ s{(
            < \s* (pre | code | textarea) [^>]* > # opening pre-, code
                                                  # or textarea tag
            .*?                                   # content
            < \s* / \2 [^>]* >                    # closing tag
            )}{\0}xmsi
    ) {
        push @unclean, $1;
    }
    ${$scalarref} =~ s{
        (?: ^ \s*)              # leading spaces and empty lines
        |
        (?: [^\S\n]* $)
        |
        ([^\S\n]* (?: \n | \z)) # spaces at EOL
        |
        ([^\S\n]{2,})           # spaces between text
    }{ $1 ? "\n" : $2 ? q{ } : q{} }xmsge;
    for my $unclean (@unclean) {
        ${$scalarref} =~ s{\0}{$unclean}xms;
    }

    return;
};

sub get_whitespace_filter {
    return $inplace_whitespace_filter;
}

sub whitespace_filter {
    my $html = shift;

    $inplace_whitespace_filter->(\$html);

    return $html;
}

# $Id$

1;

__END__