File Coverage

blib/lib/HTML/PodCodeReformat.pm

Criterion	Covered	Total	%
statement	59	61	96.7
branch	21	24	87.5
condition	2	3	66.6
subroutine	19	19	100.0
pod	2	2	100.0
total	103	109	94.5

## no critic
package HTML::PodCodeReformat;
BEGIN {
  $HTML::PodCodeReformat::VERSION = '0.20000';
}
## use critic

use strict;
use warnings;

use HTML::Parser 3.00 ();
use Carp qw(croak);

use constant MAX_INDENT => 99;

use base qw(Class::Accessor::Fast);

__PACKAGE__->mk_accessors( qw/
    squash_blank_lines
    line_numbers
    _html_parser
    _inside_pre
    _filtered_html
/);

sub new {
    my $class = shift;
    my $self = $class->SUPER::new( @_ > 1 ? { @_ } : $_[0] );
    $self->_html_parser( $self->_build_html_parser );
    return $self
}

sub _build_html_parser {
    my $self = shift;

    HTML::Parser->new(
        unbroken_text => 1,

        start_h   => [ sub { $self->_tag(@_) }, 'text, tagname, "+1"' ],
        end_h     => [ sub { $self->_tag(@_) }, 'text, tagname, "-1"' ],

        text_h    => [ sub { $self->_text(@_)             }, 'text' ],
        default_h => [ sub { $self->_append_to_output(@_) }, 'text' ]
    )
}

sub _tag {
    my ($self, $text, $tag, $incr) = @_;
    $self->_inside_pre( $incr + $self->_inside_pre )
        if $tag eq 'pre';
    $self->_append_to_output($text)
}

sub _text {
    my ($self, $text) = @_;
    $self->_append_to_output(
        $self->_inside_pre ? $self->_reformat_pre_text($text) : $text
    )
}

sub _append_to_output {
    my ($self, $text) = @_;
    $self->_filtered_html( $self->_filtered_html . $text )
}

sub _reformat_pre_text {
    my ($self, $text) = @_;

    my @lines = split /\n/, $text, -1;
    my $min_indent_width = MAX_INDENT;
    foreach ( @lines ) {
        next if /^\s*$/; # Skip verbatim paragraph breaks
                         # as well as space-only lines.
        my $indent_width = /^(\s+)/ ? length($1) : 0;
        $min_indent_width = $indent_width if $indent_width < $min_indent_width
    }

    # This test is not necessary, it's just a micro-optimization.
    if ( $min_indent_width ) {
        s/^\s{$min_indent_width}// foreach @lines
    }

    if ( $self->squash_blank_lines ) {
        s/^\s+$// foreach @lines
    }

    return $self->line_numbers
        ? '' . join( '', map { "$_" } @lines ) . ''
        : join "\n", @lines
}

sub reformat_pre {
    my ($self, $input) = @_;

    $self->_init_state;

    my $type = ref $input;
    if ( $type eq 'SCALAR' ) {
        $self->_html_parser->parse($$input);
        $self->_html_parser->eof
    } elsif ( $type eq '' || $type eq 'GLOB' ) {
        defined( $self->_html_parser->parse_file($input) ) or return
    } else {
        croak( 'Wrong input type: ', $input )
    }

    return $self->_filtered_html
}

sub _init_state {
    my $self = shift;
    $self->_filtered_html('');
    $self->_inside_pre(0)
}

1;

__END__