File Coverage

blib/lib/HTML/Lint/Pluggable.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	3	6	50.0
condition	2	3	66.6
subroutine	12	12	100.0
pod	3	4	75.0
total	66	71	92.9

package HTML::Lint::Pluggable;
use strict;
use warnings;

our $VERSION = '0.09';

use parent qw/ HTML::Lint /;

use Carp qw/croak/;
use Module::Load ();
use Package::Stash;

sub new {
    my $class = shift;

    my $subclass;
    do {
        $subclass = sprintf '%s::__ANON__::%x%x%x', $class, $$, 0+{}, int(rand(65535));
    } while $subclass->isa($class);

    push @{ Package::Stash->new($subclass)->get_or_add_symbol('@ISA') } => $class;

    return $subclass->SUPER::new(@_);
}

sub load_plugins {
    my $self = shift;
    while (@_) {
        my $plugin = shift;
        my $conf   = @_ > 0 && ref($_[0]) eq 'HASH' ? +shift : undef;
        $self->load_plugin($plugin, $conf);
    }
}

sub load_plugin {
    my ($self, $plugin, $conf) = @_;
    $plugin = "HTML::Lint::Pluggable::${plugin}" unless $plugin =~ s/^\+//;
    Module::Load::load($plugin);
    $plugin->init($self, $conf);
}

sub override {
    my ($self, $method, $code) = @_;
    my $class = ref($self) or croak('this method can called by instance only.');

    my $override_code = $code->($class->can($method));

    {
        no strict   'refs'; ## no critic
        no warnings 'redefine';
        *{"${class}::${method}"} = $override_code;
    }
}

1;
__END__