File Coverage

blib/lib/HTML/FormatText/Links.pm

Criterion	Covered	Total	%
statement	42	58	72.4
branch	1	14	7.1
condition	1	3	33.3
subroutine	13	14	92.8
pod	2	2	100.0
total	59	91	64.8

# Copyright 2008, 2009, 2010, 2013, 2015 Kevin Ryde

# HTML-FormatExternal is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as published
# by the Free Software Foundation; either version 3, or (at your option) any
# later version.
#
# HTML-FormatExternal is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License along
# with HTML-FormatExternal.  If not, see .

package HTML::FormatText::Links;
use 5.006;
use strict;
use warnings;
use URI::file;
use HTML::FormatExternal;
our @ISA = ('HTML::FormatExternal');

# uncomment this to run the ### lines
# use Smart::Comments;


our $VERSION = 23;

use constant DEFAULT_LEFTMARGIN => 3;
use constant DEFAULT_RIGHTMARGIN => 77;
use constant _WIDE_INPUT_CHARSET => 'entitize';
use constant _WIDE_OUTPUT_CHARSET => 'iso-8859-1';

# It seems maybe some people make "links" an alias for "elinks", and the
# latter doesn't have -html-margin.  Maybe it'd be worth adapting to use
# elinks style "set document.browse.margin_width=0" in that case, but for
# now just don't use it if it doesn't work.
#
use constant::defer _have_html_margin => sub {
  my ($class) = @_;
  my $help = $class->_run_version (['links', '-help']);
  return (defined $help && $help =~ /-html-margin/);
};

sub program_full_version {
  my ($self_or_class) = @_;
  return $self_or_class->_run_version (['links', '-version']);
}
sub program_version {
  my ($self_or_class) = @_;
  my $version = $self_or_class->program_full_version;
  if (! defined $version) { return undef; }

  # first line like "Links 1.00pre12" or "Links 2.2"
  $version =~ /^Links (.*)/i
    or $version =~ /^(.*)/;  # whole first line if format not recognised
  return $1 . substr($version,0,0);  # retain taintedness
}

sub _make_run {
  my ($class, $input_filename, $options) = @_;
  my @command = ('links', '-dump', '-force-html');

  if (defined $options->{'_width'}) {
    push @command, '-width', $options->{'_width'};
    if ($class->_have_html_margin) {
      push @command, '-html-margin', 0;
    }
  }

  if (my $input_charset = $options->{'input_charset'}) {
    push @command,
      '-html-assume-codepage', _links_mung_charset ($input_charset),
        '-html-hard-assume', 1;
  }
  if (my $output_charset = $options->{'output_charset'}) {
    push @command, '-codepage', _links_mung_charset ($output_charset);
  }

  # 'links_options' not documented ...
  push @command, @{$options->{'links_options'} || []};

  # links interprets "%" in the input filename as URI style %ff hex
  # encodings.  Turn unusual filenames like "%" or "-" into full
  # file:// using URI::file.
  push @command, URI::file->new_abs($input_filename)->as_string;

  return (\@command);
}

# links (version 2.2 at least) accepts "latin1" but not "latin-1".  The
# latter is accepted by the other FormatExternal programs, so turn "latin-1"
# into "latin1" for convenience.
#
sub _links_mung_charset {
  my ($charset) = @_;
  $charset =~ s/^(latin)-([0-9]+)$/$1$2/i;
  return $charset;
}


1;
__END__