File Coverage

blib/lib/HTML/Blitz/Template.pm

Criterion	Covered	Total	%
statement	84	86	97.6
branch	31	62	50.0
condition	6	15	40.0
subroutine	14	14	100.0
pod	7	8	87.5
total	142	185	76.7

package HTML::Blitz::Template;
use HTML::Blitz::pragma;
use HTML::Blitz::CodeGen ();
use Carp qw(croak);
use constant {
    _REPR_VERSION => 0,
};

our $VERSION = '0.07';

method new($class: :$_codegen) {
    bless {
        _codegen => $_codegen,
    }, $class
}

method _codegen() {
    $self->{_codegen}
}

method FREEZE($model) {
    _REPR_VERSION, $self->{_codegen}->FREEZE($model)
}

method THAW($class: $model, $repr_version, @components) {
    $repr_version <= _REPR_VERSION
        or croak "Cannot deserialize data format $repr_version with $class v$VERSION, which only supports data format " . _REPR_VERSION;
    my $codegen = HTML::Blitz::CodeGen->THAW($model, @components);
    $class->new(_codegen => $codegen)
}

method _perl_src() {
    $self->{_perl_src} //= $self->{_codegen}->assemble(
        data_format         => 'sigil',
        data_format_mapping => {
            array => '',
            bool  => '',
            func  => '',
            html  => '',
            str   => '',
        },
    )
}

method compile_to_string() {
    $self->_perl_src
}

method compile_to_fh($fh, $name = $fh) {
    print $fh $self->_perl_src
        or croak "Can't write to $name: $!";
}

method compile_to_file($file, :$do_sync = undef) {
    open my $fh, '>:encoding(UTF-8)', $file
        or croak "Can't open $file: $!";
    $self->compile_to_fh($fh, $file);
    if ($do_sync) {
        $fh->flush
            or croak "Can't flush $file: $!";
        $fh->sync
            or croak "Can't sync $file: $!";
    }
    close $fh
        or croak "Can't close $file: $!";
}

method compile_to_sub() {
    $self->{_sub} //= do {
        my $err;
        my $src = $self->_perl_src;
        my $fn;
        {
            local $@;
            $fn = eval $src;
            $err = $@;
        }
        $fn // croak $err
    }
}

method process($data = {}) {
    $self->compile_to_sub->($data)
}

1
__END__