File Coverage

blib/lib/HAL/Tiny.pm

Criterion	Covered	Total	%
statement	41	42	97.6
branch	7	10	70.0
condition			n/a
subroutine	7	7	100.0
pod	2	3	66.6
total	57	62	91.9

package HAL::Tiny;
use 5.008001;
use strict;
use warnings;

use JSON qw/encode_json/;

our $VERSION = "0.02";

sub new {
    my ($class, %args) = @_;

    my ($state, $links, $embedded)
        = @args{qw/state links embedded/};

    return bless +{
        state    => $state,
        links    => $links,
        embedded => $embedded,
    }, $class;
}

sub as_hash {
    my ($self) = @_;

    my %hash;

    if (my $state = $self->{state}) {
        %hash = %{ $self->{state} };
    }

    if (my $links = $self->{links}) {
        my $v = +{};
        for my $rel (keys %$links) {
            my $value = $links->{$rel};
            if (ref $value) {
                $v->{$rel} = $value;
            } else {
                $v->{$rel} = +{
                    href => $links->{$rel},
                }
            }
        }
        $hash{_links} = $v;
    }

    if (my $embedded = $self->{embedded}) {
        my $v = +{};
        for my $rel (keys %$embedded) {
            if (ref $embedded->{$rel} eq 'ARRAY') {
                my @hashed = map { $_->as_hash } @{$embedded->{$rel}};
                $v->{$rel} = \@hashed;
            } else {
                $v->{$rel} = $embedded->{$rel}->as_hash;
            }
        }
        $hash{_embedded} = $v;
    }

    return \%hash;
}

sub as_json {
    my ($self) = @_;
    my $hash = $self->as_hash;
    return encode_json($hash);
}


1;
__END__